اگر با اکشن اسکریپت ۲ کار کرده باشید حتما می دانید ،برای درخواست های بازکردن لینک ها و آدرس های وب و درخواست های وب از فرمان getURL استفاده می شود. البته این تابع به این شکل دیگر در اکشن اسکریپت ۳ پشتیبانی نمی شود. در این مطلب می خواهیم این تابع را با همان نام قدیمی و آرگمان های قدیمی برای اکشن اسکریپت ۳ آماده کنیم.

ابتدا کلاس های مورد نیاز را import می کنیم

import flash.net.URLRequest;
import flash.net.navigateToURL;

در مرحله بعد ما تابعی با همان نام (getURL) تعریف می کنیم و آرگمان ها را نیز به همان صورت معرفی می کنیم ، آرگمان اول در getURL مربوطه به آدرس (URL) و آرگمان دوم target که به نوع باز شدن مربوطه می شد.

function getURL(url:String, target:String = null)
{
	try
	{
		navigateToURL(new URLRequest(url), target);
	}
	catch (error:Error)
	{
		trace("[getURL] "+error);
	}
}

در نهایت بخش اصلی کد ما که آن را درون try می نویسیم تا بتوانیم خطای احتمالی آن را catch کنیم. در این بخش طبق استاندارد جدید اکشن اسکرپیت ۳ برای بازکردن لینک ها از کلاس های navigateToURL و URLRequest استفاده می کنیم. که نقش URLRequest مشخص کردن محتوای متنی به عنوان درخواست URL می باشد و نقش navigateToURL باز کردن پیوند (link) طبق آرگمان های ورودی می باشد.

حال می توانید با سرعت بیشتر و مثل تابع getURL درخواست های مربوطه به پیوند های خودتان را اجرا نمایید.

در این مطلب با یک ترفند ساده و با استفاده از کلاس‌های URLLoader و URLRequest وجود و یا عدم وجود یک فایل در ActionScript 3.0 بررسی می‌شود. بدیهی است که کاربرد اصلی این کلاس‌ها بررسی وجود و یا عدم وجود فایل نیست، اما می‌توان از آنها برای این مقصود استفاده کرد.

۱- برای این منظور ابتدا کلاس‌های مورد نیاز را import کنید.

import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.IOErrorEvent;
import flash.events.Event;

2- حالا باید یک متغیر از نوع URLLoader تعریف کنیم تا فایل مورد نظر را load کند. در این جا با تعریف دو Event Listener وضعیت لود شدن یا لود نشدن فایل را بررسی می‌کنیم.

var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE, loaded);
loader.addEventListener(IOErrorEvent.IO_ERROR, exit);

loader.load(new URLRequest("D:/Programs/Test.exe"));

دقت کنید که در معرفی آدرس فایل از / به جای \ استفاده شده است.

۳- حالا تابعی را می‌نویسیم که بعد از لود موفق فایل فراخوانی می‌شود.

function loaded(e:Event):void
{
	trace("File Exists.");
	loader.removeEventListener(Event.COMPLETE, loaded);
	loader.removeEventListener(IOErrorEvent.IO_ERROR, exit);
}

دو دستور removeEventListener برای بهینه سازی پروژه اضافه شده اند.

۴- در نهایت تابعی را می‌نویسیم که در صورت عدم لود شدن فایل فراخوانی می‌شود.

function exit(e:IOErrorEvent):void
{
	trace("File not Found.");
	loader.removeEventListener(Event.COMPLETE, loaded);
	loader.removeEventListener(IOErrorEvent.IO_ERROR, exit);
}

لازم به ذکر است که تنها عدم وجود فایل موجب فراخوانی تابع بالا نمی‌شود و ممکن است دلایل دیگری (به جز عدم وجود فایل) موجب بروز خطا شود.

در این مطلب نحوه فشرده سازی فایل‌ها به صورت zip و استخراج فایل‌های فشرده شده با فرمت zip و نمایش لیست محتویات فایل zip آموزش داده می‌شود. همچنین در این درس استفاده از کلاسه‌های swc آموزش داده می‌شود.

دانلود : components.zip | source_extract_zip_list.zip

قبل از شروع فایل components.zip را دانلود کنید و فایل‌های داخل آنرا با توجه به محل نصب Flash در پوشه libs کپی کنید.

install Path:
\Adobe\Adobe Flash CS5\Common\Configuration\ActionScript 3.0\libs

فشرده سازی فایل‌ها

۱- برنامه Flash را اجرا کنید.

۲-  یک پروژه جدید Air ایجاد کنید.

۳- حال کلاسه‌های مورد نظر را import کنید.

import deng.fzip.*;
import deng.utils.ChecksumUtil;
import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;

4- در ادامه باید ۳ متغیر ایجاد کنید و فایل مورد نظر را که می‌خواهید فشرده شود تعریف نمایید.

var zip:FZip = new FZip();
var ba:ByteArray = new ByteArray();
var file:File = new File();

5- با کد resolvePath فایل مورد نظر را به کلاسه File معرفی کنید. (به جای c:/test.txt آدرس فایل مورد نظرتان را بنویسید. دقت کنید که به جای “\” از “/” استفاده نمایید.)

file = file.resolvePath("c:/test.txt");

6- حال باید فایل مورد نظر و محتویات آنرا به متغیر zip معرفی کنید. همچنین واسطه ByteArray را هم باید به zip معرفی کنید.

zip.addFile(file.name,file.data);
zip.serialize(ba);
ba.position = 0;

7- در نهایت نیاز است که آدرس فایل خروجی (با فرمت zip) را تعریف کرده و به وسیله یک FileStream اطلاعات تبدیل شده را روی آن دخیره کرد.

var finalZip:File = File.desktopDirectory.resolvePath(“test.zip”);
var fs:FileStream = new FileStream();
fs.open(finalZip,FileMode.WRITE);
fs.writeBytes(ba);
fs.close();

استخراج فایل Zip

1- یک پروژه جدید Air ایجاد کنید.

۲- از منوی Window پنل Components را فعال کنید.

۳- از دسته User Interface گزینه Button را انتخاب کنید و ۲ بار آنرا به داخل صفحه Drag کنید.

۴- در پنل Properties، نام Instance دکمه‌ها را به ترتیب load_btn و extract بگذارید و تنظیمات مربوطه را به صورت زیر انجام دهید.

۵- حال کلاسه‌های مورد نظر را import کنید و متغیرهای مورد نیاز را برای تعریف فایل zip ایجاد کنید.

import flash.filesystem.*;
import flash.net.FileFilter;
import nochump.util.zip.*;
import flash.events.Event;
var zipInput:File = new File();
var zipOutput:File = new File();
var zipFile:ZipFile;

6- در ادامه برای هر دکمه یک Event Listener تعریف کنید تا در هر بار کلیک توابع مربوطه اجرا شود.

load_btn.addEventListener("click", loadZIP);
extract.addEventListener("click", extractZIP);

7- تابع loadZip را که بعد از کلیک روی دکمه load_btn فراخوانی می‌شود، به صورت زیر تعریف کنید. بعد از کلیک روی این دکمه یک پنجره برای انتخاب فایل zip اجرا می‌شود.

function loadZIP(e:Event):void
{
	var filter:FileFilter = new FileFilter("ZIP","*.zip");
	zipInput.browseForOpen("Open ZIP file",[filter]);
	zipInput.addEventListener(Event.SELECT, onSelect);
}

اجزای مختلف این تابع به صورت زیر است:

• filter: یک متغیر از نوع FileFilter برای تعریف فرمت Zip که بعد از کلیک روی دکمه مربوطه در پنجره انتخاب فایل نمایش داده می‌شود.
• browseForOpen: پنجره انتخاب فایل را نشان می‌دهد و عنوان آن در اینجا برای مثال “Open Zip file” و فرمت فایل‌های انتخابی filter می‌باشد.

۸- حال باید تابع onSelect را که بعد از انتخاب فایل فراخوانی می‌شود، تعریف کنید.

function onSelect(e:Event):void
{
	var stream:FileStream = new FileStream();
	stream.open(zipInput,FileMode.READ);
	zipFile = new ZipFile(stream);
	extract.enabled = true;
}

در این تابع:

• stream: متغیری از نوع FileStream است که فایل zip انتخاب شده را در برنامه به جریان می‌اندازد.
• zipFile: متغیری است که در ابتدا ایجاد شد و در اینجا stream به آن معرفی می‌شود.

۹- تابع extractZIP که بعد از کلیک روی دکمه extract فراخوانی می‌شود، به صورت زیر تعریف می‌شود. در این تابع یک پنجره برای انتخاب پوشه مقصد (جایی که فایل zip باید استخراج شود) نمایش داده می‌شود.

function extractZIP(e:Event):void
{
	zipOutput.browseForDirectory("Select Directory for extract");
	zipOutput.addEventListener(Event.SELECT, onDirSelect);
}

10- درنهایت تابع onDirSelect را که بعد از انتخاب پوشه مقصد فراخوانی می‌شود، به صورت زیر تعریف کنید.

function onDirSelect(e:Event):void
{
	for (var i:uint = 0; i<zipFile.entries.length; i++)
	{
		var zipEntry:ZipEntry = zipFile.entries[i] as ZipEntry;
		if (! zipEntry.isDirectory())
		{
			var targetDir:File = e.target as File;
			var entryFile:File = new File();
			entryFile = targetDir.resolvePath(zipEntry.name);
			var entry:FileStream = new FileStream();
			entry.open(entryFile, FileMode.WRITE);
			entry.writeBytes(zipFile.getInput(zipEntry));
			entry.close();
		}
		trace("Finished.");
	}
}

در این تابع:

• یک حلقه for ایجاد شده است که به تعداد فایل‌های داخل فایل zip تکرار می‌شود.
• در داخل حلقه یک متغیر از نوع ZipEntry تعریف شده است که محتویات فایل zip را یکی یکی معرفی می‌کند.
• همچنین در داخل حلقه، یک دستور if وجود دارد که مطمئن می‌شود، فایل ورودی از zipEntry یک پوشه نباشد.
• در ادامه فایل ورودی به وسیله یک FileStream در پوشه مقصد ذخیره می‌شود.
• در نهایت بعد از تکمیل استخراج فایل zip، عبارت Finished نشان داده می‌شود.

نمایش فهرست فایل‌های داخل Zip

با استفاده از کلاسه‌های swc نصب شده در ابتدای این درس می‌توانید فهرست فایل ‌های داخل Zip را نمایش دهید. بدین منظور از کدهای زیر استفاده کنید.

import deng.fzip.*;
import deng.utils.ChecksumUtil;
import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.events.Event;
import flash.net.URLRequest;

var zip:FZip = new FZip();
zip.addEventListener(FZipEvent.FILE_LOADED, fileLoaded);
zip.load(new URLRequest("d:/test.zip"));

function fileLoaded(e:FZipEvent):void
{
	var file:FZipFile = e.file;
	trace("File Loaded: " + file.filename);
	trace(" " + file.sizeCompressed);
	trace(" " + file.sizeUncompressed);
}

در این مطلب به روش بارگزاری یک فایل قالب بندی CSS و اعمال آن به یک فیلد متنی (Text Fild) می پردازیم ، فایل Css ما خارج از پروژه می باشد (External) ما بعد از بارگزاری آن و آماده سازی ،آن را به باکس متنی خود اعمال می کنیم. این روش برای محتوای HTML بارگزاری شده در تکست فیلد های کاربرد زیادی دارد و می توانید توسط این روش بعد از اتمام پروژه بدون تغییر در فایل فلش تغییرات مورد نیاز خود را روی متون و قالب بندی آنها سایز ، رنگ و دیگر خصوصیات که توسط CSS قابل تنظیم هست ،به روز رسانی کنید.

ابتدا ما فایل ساده ای را به عنوان فایل CSS خود ایجاد می کنیم می توانید این فایل را توسط هر ویرایشگر متنی ایجاد نمایید ، نام فایل را  content.css قرار می دهیم. فایل را در کنار فایل فلش خود قرار دهید.

p {

font-size: 40px;
color: #ff0000;

}

حال در برنامه فلش پروژه ای جدید ایجاد می کنیم و کلاس های مورد نیاز را در بخش اکشن وارد می کنیم

import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.text.StyleSheet;
import flash.events.Event;

حال توسط کدهای زیر فایل را بارگزاری می کنیم تا بتوانیم آن را در مراحل بعد استفاده کنیم

//css تعریف بارگزارنده فایل قالب بندی
var cssLoader:URLLoader = new URLLoader();

//مشخص کردن آدرس و نام فایل خارجی
var cssRequest:URLRequest = new URLRequest("content.css");

//فراخوانی متد مربوطه به بارگزاری فایل تعیین شده
cssLoader.load(cssRequest);

//تعریف رویداد برای زمان کامل شدن بارگزاری
cssLoader.addEventListener(Event.COMPLETE, cssLoadComplete);

در مرحله بعد یک نمونه از کلاس StyleSheet را برای دریافت و آماده سازی محتوای قالب بندی تعریف می کنیم و سپس تابع  cssLoadComplete را برای کنترل کردن رویداد کامل شدن بارگزاری تعریف می کنیم

//StyleSheet تعریف کلاس
var sheet:StyleSheet = new StyleSheet();

//تعریف تابعی برای زمان کامل شدن بارگزاری
function cssLoadComplete(event:Event):void
{

	// چاپ محتوای بارگزاری شده برای تست
	//trace(cssLoader.data);

	//افزودن محتوای بارگزاری شده به کلاس استایل شیت و تبدیل محتوای متنی برای پردازش قالب بندی
	sheet.parseCSS(cssLoader.data);

	// حال می توانیم استایل شیت آماده شده را به تکست فیلد خود اعمال کنیم
	// مربوطه به تکست فیلد مربوطه استفاده می کنیم styleSheetبرای این کار از متد
	textBox.styleSheet = sheet;

	//

	//برای مثال
	textBox.text = "<p>test css iflashlord</p>";

}

همان طور که در کد تابع  مشاهده می کنید بعد از بارگزاری کامل محتوای بارگزاری شده که توسط cssLoader.data قابل دریافت هست را توسط متد parseCSS به sheet تعریف شده اعمال می کنیم ،و در مرحله بعد sheet را به خصوصیت styleSheet تکست فیلدمان (در این مثال textBox) اختصاص می دهیم.

حال می توانیم محتوای خود را به تکست فیلد اعمال کنیم و یا محتوای خارجی External خود را بارگزاری کرده و به تکست فیلد اعمال کنیم.

در این حالت محتوای تکست فیلد از قالب بندی تعریف شده استفاده می کند برای مثال متن نمونه به صورت قرمز و سایز ۴۰  نمایش داده خواهد شد.

توجه داشته باشد که خصوصیت html مربوطه تکست فیلد برای آنلالیز محتوای HTML می بایست فعال شده باشد.

در این مطلب نحوه برقراری ارتباط با RSS یک وبسایت و دریافت اطلاعات آن به صورت XML آموزش داده می‌شود. بعد از دریافت اطلاعات به راحتی می‌توانید به کمک کدهای XML از این اطلاعات استفاده کنید.

۱- برای شروع لازم است که کلاسه‌های مورد نیاز را import کنید.

import flash.net.URLLoader;
import flash.events.Event;
import flash.net.URLRequest;

2- حالا یک متغیر از نوع URLLoader می‌سازیم، یک Event Listener برای آن تعریف می‌کنیم تا از کامل شدن دریافت اطلاعات آگاه شویم. سپس آدرس مورد نظر را Load می‌کنیم.

var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE, loaded);
loader.load(new URLRequest("http://blog.iflashlord.com/feed/"));

3- در نهایت تابع loaded را که بعد از کامل شدن دریافت اطلاعات فراخوانی می‌شود، تعریف می‌کنیم.

function loaded(e:Event):void
{
	var xml:XML = XML(e.target.data);

	// Method 1:
	var xmlList:XMLList = xml.channel..item;

	// Method 2:
	//var xmlL:XMLList = xml.channel.elements("item");

	trace(xmlList.length());
	trace(xmlList[2]);
}

در این تابع:

• ابتدا اطلاعات دریافت شده به صورت XML تبدیل شده و در یک متغیر از نوع XML قرار می‌گیرند.
• در بین اطلاعات دریافت شده، element‌های item شامل اطلاعات هر پست هستند. برای جداسازی آنها از دو روش می‌توان استفاده کرد. بعد از جداسازی آنها را در یک متغیر از نوع XMLList ذخیره می‌کنیم.
• در نهایت نحوه استفاده از اطلاعات در دو مثال آمده است. (دستورات trace)

در این درس نحوه دانلود فایل از روی Server و ذخیره سازی آن آموزش داده می‌شود. در صورتی که قرار باشد پروژه روی Desktop کار کند باید از پروژه Air استفاده شود، در غیر اینصورت می‌توانید از پروژه Action Script 3.0 استفاده کنید. در هر دو حالت عملیات دانلود توسط FileReference و بدون نیاز به هیچ واسطه PHP انجام می‌شود.

دانلود سورس: sourceCS5.zip

1- با توجه به نیاز خود یک پروژه Air و یا AS3 بسازید.

۲- ابتدا لازم است که فرم زیر را طراحی کنید.

۳- برای ادامه کلاسه‌های مورد نیاز را import کنید.

import flash.events.Event;
import flash.net.FileReference;
import flash.net.URLRequest;
import flash.events.ProgressEvent;

4- حالا به دو متغیر از نوع FileReference و URLRequest نیاز داریم. به کمک متغیر URLRequest آدرس فایل مورد نظر را برای دانلود به متغیر FileReference  معرفی خواهیم کرد.

var downloader:FileReference;
var Request:URLRequest;

5- قصد داریم در این مثال بعد از کلیک روی download_mc عملیات دانلود شروع شود. پس Event Listener مربوطه را به صورت زیر تعریف می‌کنیم، همچنین این MovieClip در حالت Button قرار گرفته است (البته این کار ضروری نیست).

download_mc.buttonMode = true;
download_mc.addEventListener("click", Start);

6- حالا تابع Start را که بعد از کلیک روی download_mc فراخوانی می‌شود، تعریف می‌کنیم.

function Start(e:Event):void
{
	download_mc.removeEventListener("click", Start);
	mc_loaded.scaleX = 0;
	downloader = new FileReference();
	Request = new URLRequest();
	downloader.addEventListener(ProgressEvent.PROGRESS, Progress);
	downloader.addEventListener(Event.COMPLETE, Complete);
	downloader.addEventListener(Event.CANCEL, Cancel);
	Request.url = url_txt.text;
	downloader.download(Request);
	url_txt.text = "Downloading ...";
}

در این تابع:

• ابتدا Event Listener مربوط به کلیک حذف می‌شود تا کاربر قبل از تکمیل دانلود نتواند دوباره این تابع را فراخوانی کند.
• mc_loaded در حالت آماده برای نشان دادن مقدار پیشرفت دانلود قرار می‌گیرد.
• یک شیء جدید برای FileReference و URLRequest ساخته می‌شود.
• سه Event Listener برای FileReference به منظور نشان دادن تکمیل و حین و لغو دانلود تعریف می‌شود.
• آدرسی که کاربر در فیلد متنی url_txt نوشته است به URLRequest منتقل می‌شود.
• آدرس فایل توسط URLRequest به FileReference معرفی می‌شود و کاربر پنجره ذخیره فایل را خواهد دید.

۷- حالا باید توابع مربوط به سه وضعیت لغو، حین و تکمیل دانلود که در زمان‌های مختلف توسط FileReference فراخوانی می‌شوند را تعریف کنیم.

function Cancel(e:Event):void
{
	url_txt.text = "";
	download_mc.addEventListener("click", Start);
	downloader.removeEventListener(Event.CANCEL, Cancel);
	downloader.removeEventListener(ProgressEvent.PROGRESS, Progress);
	downloader.removeEventListener(Event.COMPLETE, Complete);
}

function Progress(e:ProgressEvent):void
{
	mc_loaded.scaleX = (e.bytesLoaded / e.bytesTotal) ;
}

function Complete(e:Event):void
{
	url_txt.text = "Download Finished.";
	download_mc.addEventListener("click", Start);
	downloader.removeEventListener(Event.CANCEL, Cancel);
	downloader.removeEventListener(ProgressEvent.PROGRESS, Progress);
	downloader.removeEventListener(Event.COMPLETE, Complete);
}

همانطور که مشخص است بعد از لغو و یا تکمیل دانلود دوباره وضعیت کلیک برای download_mc فعال می‌شود و Event Listener‌های مربوط به FileReference حذف می‌شوند. در حین دانلود هم mc_loaded درصد پیشرفت دانلود را نشان می‌دهد.

+ منبع

در این مطلب نحوه برقراری ارتباط بین Air و PHP به منظور Upload فایل روی Server آموزش داده می‌شود. ابتدا یک فرم مخصوص آپلود می‌سازیم، سپس کدهای مربوط به PHP را نوشته و فایل‌های مورد نیاز را روی Server قرار می‌دهیم. در نهایت کدهای مربوط به نرم افزار را در Flash اضافه می‌کنیم. برای آپلود فایل‌ها از FileReference، URLRequest و URLVariables استفاده می‌کنیم.

دانلود سورس : Source CS5.5.zip

1- برای شروع یک پروژه جدید Air ایجاد کنید.

۲- به کمک کامپوننت‌های Button , Text Input و به کمک ابزار Rectangle این فرم را بسازید.

۳- یک برنامه Editor باز کنید و این کدها را در آن بنویسید، سپس فایل را با نام uploader_script.php ذخیره کنید.

<?php $todayDate = $_POST['todayDate'];
$Name = $_POST['Name'];
$Email = $_POST['Email'];
$filename = $_FILES['Filedata']['name'];
$filetmpname = $_FILES['Filedata']['tmp_name'];
$fileType = $_FILES["Filedata"]["type"];
$fileSizeMB = ($_FILES["Filedata"]["size"] / 1024 / 1000);
move_uploaded_file($_FILES['Filedata']['tmp_name'], "images/".$filename);
$myFile = "logFile.txt";
$fh = fopen($myFile, ‘a’) or die("can’t open file");
$stringData = “\n\ntodayDate: $todayDate \n Name: $Name \n Email: $Email \n ssid: $ssid \n FileName: $filename \n TmpName: $filetmpname \n Type: $fileType \n Size: $fileSizeMB MegaBytes”;
fwrite($fh, $stringData);
fclose($fh);
?>

• در این کدها ابتدا اطلاعات با متد POST دریافت می‌شود.
• سپس فایل‌های آپلود شده به داخل فولدر images که در کنار همین فایل PHP باید بسازیم منتقل می‌شوند و نام اصلی فایل برای آن حفظ می‌شود.
• در ادامه اطلاعات مربوط به فایل در یک فایل متنی به نام logFile.txt ذخیره می‌شود.

۴- حالا فایل PHP را در Server خود آپلود کنید. در کنار این فایل یک فولدر به نام images و یک فایل متنی به نام logFile.txt ایجاد کنید و Permission آنها را ۷۷۷ قرار دهید.

۵- پنل Actions را برای فریم اول پروژه فلش فعال کنید.

۶- حالا باید کلاسه مورد نیاز را import کنید:

import flash.net.URLRequest;
import flash.net.FileFilter;
import flash.net.FileReference;
import flash.events.ProgressEvent;
import flash.events.Event;
import flash.net.URLRequestMethod;
import flash.net.URLVariables;

7- اطلاعات اولیه مربوط به دکمه‌ها و سایر قسمت‌هایی را که در فرم بالا قابل مشاهده هستند، به صورت زیر تعریف کنید:

upload_btn.enabled = false;
progressBar.width = 1;
uploadMsg.text = "Select a File …";

۸- متغیر URLRequest را که به آدرس فایل PHP بر روی Server متصل می‌شود، به صورت زیر تعریف کنید:

var URLrequest:URLRequest = new URLRequest("uploader_script.php");

9- در این آموزش در نظر داریم که کاربر فقط بتواند فایل عکس و متن را با برنامه آپلود کند، بنابراین فیلتر فایل‌ها را به صورت زیر تعریف می‌کنیم و هر دو نوع فیلتر را در یک آرایه قرار می‌دهیم:

var imageTypes:FileFilter = new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg; *.jpeg; *.gif; *.png”);
var textTypes:FileFilter = new FileFilter("Text Files (*.txt, *.rtf)", "*.txt; *.rtf");
var allTypes:Array = new Array(imageTypes, textTypes);

10- یک FileReference جدید می‌سازیم و Event Listener‌های مربوط به انتخاب موفق فایل توسط کاربر، کامل شدن آپلود و حین پیشرفت آپلود را برای آن به صورت زیر تعریف می‌کنیم:

var fileRef:FileReference = new FileReference();
fileRef.addEventListener(Event.SELECT, syncVariables);
fileRef.addEventListener(Event.COMPLETE, completeHandler);
fileRef.addEventListener(ProgressEvent.PROGRESS, progressHandler);

11- حالا Event Listener‌های مربوط به کلیک روی دکمه‌ها را تعریف کنید.

browse_btn.addEventListener(MouseEvent.CLICK, browseBox);
upload_btn.addEventListener(MouseEvent.CLICK, uploadVars);

12- تابعی که بعد از کلیک روی دکمه Browse فراخوانی می‌شود، به صورت زیر تعریف می‌شود. بعد از کلیک روی این دکمه کاربر باید پنجره انتخاب فایل را با فیلترهایی که قبلا آماده شدند، ببیند.

function browseBox(event:MouseEvent):void
{
	fileRef.browse(allTypes);
}

13- تابعی که بعد از انتخاب موفق فایل توسط کاربر، فراخوانی می‌شود، به صورت زیر تعریف می‌شود. در این تابع ابتدا آدرس فایل در فیلد مربوطه نشان داده می‌شود. سپس دکمه آپلود فعال و ProgressBar آماده می‌شود، در ادامه اطلاعات مورد نیاز PHP به کمک URLVariables جمع آوری می‌شود و این اطلاعات توسط متد POST برای PHP آماده ارسال می‌شوند.

function syncVariables(event:Event):void
{
	fileDisplay_txt.text = "" + fileRef.name;
	upload_btn.enabled = true;
	progressBar.width = 1;
	var variables:URLVariables = new URLVariables();
	variables.todayDate = new Date();
	variables.Name = "IFLashLord";
	variables.Email = "test@gmail.com";
	URLrequest.method = URLRequestMethod.POST;
	URLrequest.data = variables;
}

14- حالا وقت آن رسیده است تابعی را تعریف کنیم که بعد از کلیک روی دکمه Upload فراخوانی می‌شود و اطلاعات را به PHP می‌فرستد. یکی از این اطلاعات، خود فایل انتخاب شده است که با دستور upload توسط FileReference ارسال می‌شود.

function uploadVars(event:MouseEvent):void
{
	uploadMsg.text = "Uploading …";
	fileRef.upload(URLrequest);
	upload_btn.enabled = false;
}

15- توابع مربوط به کامل شدن و حین پیشرفت آپلود به صورت زیر تعریف می‌شوند.

function completeHandler(event:Event):void
{
	uploadMsg.text = fileRef.name + " has been uploaded.";
	fileDisplay_txt.text = "";
}

function progressHandler(event:ProgressEvent):void
{
	progressBar.width = Math.ceil(241 * (event.bytesLoaded / event.bytesTotal));
}

در صورتی که نیاز داشتید می‌توانید این پروژه را به صورت swf و AS3 در کنار فایل PHP آپلود کنید. اما اگر قرار است این برنامه بر روی Desktop کار کند حتما باید از پروژه Air استفاده کنید.

//ساخت یک شی از نوع کلاس بارگزارنده
var my_Loader:Loader = new Loader();

//تعریف متغییری از نوع مووی کلیپ
var my_loadedSwf:MovieClip;

//با تعریف رویداد برای بارگزارنده زمان پایان بارگزاری فایل فلش خارجی (خارج از پروژه) خود را متوجه می شویم
my_Loader.contentLoaderInfo.addEventListener(Event.COMPLETE, finishLoading);

//توسط این خط رویداد های مربوطه به خطا ها را دریافت می کنیم
my_Loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

//سپس توسط فرمان زیر فایل مورد نظر خودمان را در بارگزارنده بارگزاری می کنیم
my_Loader.load(new URLRequest("test.swf"));

// به طور ما درون فایل مربوطه تابعی با نام
//testing()
// تعریف کرده ایم و برای دریافت آن محتوای بارگزاری شده را به یک متغییر انتقال می دهیم.

//تابع مربوطه به زمان بارگزاری کامل
function finishLoading(loadEvent:Event) {
my_loadedSwf = loadEvent.currentTarget.content;

addChild(my_loadedSwf);

//توسط خط زیر تابع درون فایل خارجی ما فراخوانی می شود
my_loadedSwf.testing();
}

// هندل کردن رویدادهای خطا
function errorHandler(errorEvent:Event):void {
trace("فایل یافت نشد!");
}

بهینه سازی در فلش یک اصل مهم به حساب می آید و افزایش و کار بر روی آن برای توسعه دهندگان فلش امری الزامی است. به عنوان یک توسعه دهنده فلش و به عنوان کسی که برای آینده این نرم افزار بزرگ احساس مسئولیت می کند ، ما وظیفه داریم در ساخت عناصر فلش که کارایی بهتری دارند پیش گام باشیم و همواره بهترین و بهینه ترین روش را استفاده کنیم. در این مجموعه آموزشی بهینه سازی فلش به نکات مهم برای مدیریت بر عناصر و حافظه ها … می پردازیم و تلاش می کنیم که بتوانیم با استفاده از نکات ارائه شده خروجی بهینه تر و سبک تری از پروژه فلش خود داشته باشیم.

بخش ششم – unloadAndStop در فلش پلیر ۱۰

متد unloadAndStop در پاسخ به چالش های پیش روی توسعه دهندگان اکشن اسکریپت برای توقف محتوای swf بارگزاری شده و حذف آن از حافظه (Memory) ، به اکشن اسکریپت در فلش پلیر ۱۰ افزوده شد.

البته این مورد افزوده شده را نمی توان مانند گلوله ای جادویی برای حل همه مشکلاتی که در این زمینه وجود دارد دانست! ، برای روشن شدن بیشتر توضیح می دهیم که این مورد چه کاری انجام می دهد ، در مرحله اول این متد تلاش می کند محتوای بارگزاری شده را برای جمع آوری آماده کند ، و در مرحله بعد به جمع آورنده زباله (Garbage Collector) که می بایست عملیات جمع آوری زباله را انجام دهد ارجاع می شود. شما می توانید از مرحله دوم (که همان جمع آوری زباله gc می باشد)  با دادن مقدار false به عنوان آرگمان اول متد ، جلوگیری به عمل آورید.

با استفاده از این متد دریافت فایل swf باقی مانده در حافظه ساده می باشد ، اما انجام این کار به صورت تصادفی خیلی دشوار تر می باشد.

در زیر به فهرستی از مواردی که unloadAndStop آنها را برای فایل های swf بارگزاری شده آماده می کند را مشاهده می کنید :

* ایست کردن تمامی MovieClip ها
* ایست کردن تمامی صداهای در حال پخش و Stream (پخش در جریان)
* ایست و حذف همه تایمر (Timer) های استفاده شده
* حذف همه شنونده های رویداد عمومی ، برای enterFrame , exitFrame , frameconstructed , activeate , deactivate
* حدف همه شنونده های مربوطه به  stage که توسط فرزند (child) ایجاده شده است
* بستن همه NetConnection ها و NetStream ها (Video.attachNetStream/attachCamera(0) – Microphone.setLoopback(0))
* حدف فونت های AS3 از جدول فونت های عمومی
* ایست ؛ socket ها ، xmlsocket ها ،دانلودهای filerefrence ، و دیگر اشاء مربوطه به دانلود (grandchildren (سطح نوه والد) ) و…
* آزاد کردن bitmap های در ارتباط با cacheAsBitmap و filterها و…

تذکر : تمامی موارد بالا به صورت بازگشتی اجرا می شوند ، به طوری که این موارد به هر یک از فرزندان تو در تو (nested) و فایل های swf بارگزاری شده در آن ها ، نیز اعمال می شود.

حال به مثالی در این زمینه می پردازیم :

var loader:Loader = new Loader();

loader.load( new URLRequest ( "sample_content.swf" ) );

addChild( loader );

stage.addEventListener( MouseEvent.CLICK, unloadSWF );

function unloadSWF( e:MouseEvent ):void
{
	//unloadAndStop استفاده از متد
	loader.unloadAndStop();
}

در کد بالا ابتدا یک شی Loader ساخته می شود و فایل نمونه آزمایشی ما را با نام sample_content.swf را بارگزاری می کند و سپس شی به DisplayObject افزوده (addChild) می شود.

در مرحله بعد با رویدادی که برای کلیک موس در stage در این مثال ایجاد می کنیم در زمان کلیک تابع unloadSWF را فراخوانی می کنیم

در این تابع با استفاده از متد unloadAndStop عمل unload را انجام می دهیم.

موفق و پیروز باشید.

ذخیره کردن و بارگزاری و استفاده از فایل های متنی و XML در اکشن اسکریپت ۳ به صورت دو دویی (Binary) امکان جدیدی می باشد ، که برای فایل های خارجی با حجم بالا استفاده زیادی دارد.

فایل های XML طولانی می بایست به صورت run-time بارگزاری شود ، با ذخیره XML به صورت Binary شما می توانید اطلاعات را فشرده سازی (compress) کنید و فایل با حجم کمتری دریافت نمایید.

البته میزان فشرده سازی وابسته به پیچیدگی اطلاعات فایل شما می باشد ، اما این فشرده سازی به طور معمول بیشتر از ۵۰% انجام می شود.

مسلما استفاده از اطلاعات XML به صورت فشرده شده و در قالب Binary با روشی که به صورت ساده و در قالب متنی ، برای XML استفاده می شود متفاوت است. بنابراین شما می بایست قبل از شروع به کار تصمیم خود را در مورد پروژه خود بگیرید. ممکن هست اطلاعات سری و امنیتی به صورت خارجی دارید و یا اطلاعات دارید که می خواهید بدون نیاز به کد گذاری دوباره بتوانید آن را تغییر دهید،  و در عین حال ترجیح می دهید که محتوا برای انسان غیر قابل درک باشد ، در مرحله بعد به تبدیل محتوای متنی به دودویی می پردازیم.

تبدیل XML به دو دویی(Binary) توسط کلاس ByteArray :

ابتدا به این موضوع می پردازیم که چگونه اطلاعات XML را در یک ByteArray دخیره کنیم. در کد زیر ما قبلا اطلاعات XML را به صورت رشته متنی (String) در متغیری با نام xmlData قرار داده ایم. که می توانید این کار را یا توسط بارگزاری اطلاعات انجام دهید و یا از XML داخلی فلش استفاده نمایید.

var data:ByteArray = new ByteArray();
data.writeUTFBytes(xmlData); // xmlData فایل ایکس ام ال اصلی ما می باشد
data.compress();

با استفاده از این کدها ، هم اکنون متغیر data از نوع ByteArray شامل محتوای فشرده شده فایل XML به صورت دو دویی (Binary) می باشد.

ذخیره به صورت یک فایل :

حال شما اطلاعات Binary از نوع ByeArray را دارید ، شما می توانید آن را به صورت یک فایل خام ذخیره کنید ، برای این کار شما گزینه های زیر را پیش رو دارید:

۱ – ارسال به سرور و ذخیره اطلاعات توسط واسط سمت سرور.
۲ – استفاده از امکاناتی که Adobe Air در اختیار شما قرار می دهد برای ذخیره بر روی دیسک سخت.
۳ – استفاده از فلش پلیر ورژن ۱۰ برای ذخیره بر روی دیسک سخت.

در این آموزش ما گزینه ۳ را انتخاب می کنیم زیرا برای اکثر توسعه دهندگان فلش در دسترس می باشد و نیز با امکانات جدید فلش پلیر ۱۰ به بالا نیز بیشتر آشنا می شویم.

کلاسی می بایست برای این امر از آن استفاده کنیم flash.net.FileReference می باشد، متد (method) مربوطه به ذخیره FileRefrence.save() می باشد و به کاربر امکان دادن مسیر ذخیره فایل را می دهد ، با این امکان شما می توانید اطلاعات خود را مانند یک فایل بر روی سیستم کاربر ذخیره کنید ، البته برای ذخیره کاربر امکان تغییر نام و مسیر فایل مورد نظر شما را خواهد داشت و البته یک مزیت این روش مناسب بودن برای نمونه های تحت وب است.

به عنوان یک اقدام امنیتی فلش پلیر نتها در صورتی این دستور را اجرا می کند که شما آن را با تعیین یک رویداد به کاربر نمایش دهید مانند (رویداد MouseEvent.CLICK).  به هر حال شما نیاز دارید یک دکمه (button) ایجاد کنید و شنونده (listener) مربوطه به رویداد را به آن اضافه کنید و در تابع مربوطه متد save() را فراخوانی کنید

function on_buttonClick(evt:MouseEvent):void
{
	var data:ByteArray = new ByteArray();
	data.writeUTFBytes(xmlData);
	// xmlData فایل اصلی ایکس ام ال در قالب متنی;
	data.compress();
	new FileReference  .save(data, "bindata.xml");
}//"bindata.xml" نام پیش فرض

فرمان save() کادر محاوره ای باز می کند که شما می توانید نام فایل و محل ذخیره سازی را به دلخواه مشخص نمایید و بر روی سیستم ذخیره نمایید ، توجه داشته باشید با این که در این مورد ما پسوند فایل را xml قرار دادیم ولی این فایل با فرمت (extension) دو دویی (binary) تبدیل شده است و محتوای آن عملا دیگر برای انسان قابل فهم نمی باشد و در صورتی که با یک ویرایشگر متنی فایل را مشاهده نمایید محتوای آن تشکیل شده است از متون در هم ریخته که مفهومی ندارد و دلیل این امر نیز فشرده شدن و تبدیل به دودویی (binary) می باشد.

شما می توانید این فایل را در هر پسوند دیگری به صورت دلخواه نیز ذخیره کنید و از آن استفاده نمایید.

بارگزاری فایل XML دو دویی (Binary) :

حال شما فایلی دارید که به صورت دو دویی می باشد ولی محتوای آن فایل xml  شماست ، حال برای استفاده و بارگزاری آن شما می بایست از روش زیر استفاده کنید. در نهایت محتوای بارگزاری شده در فلش مانند فایل ساده ی xml بوده و تمامی دسترسی هایی که در زمان بارگزاری و استفاده از یک فایل xml ساده دارید را همچنان بدون هیچ محدودیتی در اختیار دارید.

var ldr:URLLoader = new URLLoader();
ldr.dataFormat = URLLoaderDataFormat.BINARY;// ** مطمئن شوید این خط کد را نوشته اید **
ldr.addEventListener(Event.COMPLETE, on_XML);
ldr.addEventListener(IOErrorEvent.IO_ERROR, on_XML);
ldr.load(new URLRequest(pathToXMLFile));

این کد برای بارگزاری فایل XML مانند یک فایل XML ساده می باشد ، تنها تفاوتی که وجود دارد در این می باشد که شما می بایست dataFormat را نیز تعیین نمایید و آن را برای فایل دو دویی به صورت URLLoaderDataFormat.BINARY مقدار دهی نمایید. حتی اگر شما این فایل را به صورت ساده بارگزاری کنید کد می بایست به درستی کار کند.

تبدیل فایل دو دویی(Binary) به XML توسط کلاس ByteArray :

بعد از این که بارگزاری داده های binary فایل XML ما انجام شد می بایست اطلاعات دو دویی را به اطلاعات متنی XML تبدیل نماییم.

var xmlData:XML;

function on_XML(evt:Event):void
{
	if (evt.type == Event.COMPLETE)
	{
		var data:* = URLLoader(evt.target).data;
		if (data is ByteArray)
		{
			try
			{
				ByteArray(data).uncompress();
			}
			catch (e:Error)
			{
			}
		}
		xmlData = XML(data);
	}
}

با کد بالا برنامه شما می تواند هر دو نوع فایل text XML و binary XML را دریافت کند ،شما می توانید این کد را حتی در زمانی که فایل XML شما فشرده شده و به صورت دو دویی نمی باشد نیز استفاده کنید. با این کار در صورتی که شما در زمانی تصمیم گرفتید که از اطلاعات XML به صورت فشرده شده Binary در برنامه خود استفاده کنید می توانید این کار را به راحتی و بدون هیچ تغییری انجام دهید و برنامه به درستی این نوع فایل را دریافت خواهد کرد.

در پایان توجه داشته باشید این روش را می توانید برای هر فایل متنی استفاده کنید و تنها برای فایل های XML نمی باشد.

موفق و پیروز باشید.