در این مطلب می خواهیم به روشی ساده برای اعمال افکت blur به یک شی از نوع BitmapData بپردازیم. توجه داشته باشید این نوع اعمال افکت با افکت ها و Filterهای معمول فلش متفاوت هست و بر روی خود BitmapData اعمال می شود و نه بر روی MovieClip ی که تصویری در آن قرار دارد.

دانلود سورس : blur_effect_bitmapdata_iflashlord.zip 

یک پروژه جدید در نرم افزار ادوبی فلش ایجاد نمایید و یک تصویر را وارد برنامه کنید (Ctrl+R) در این مثال ما از تصویر زیر استفاده کرده ایم.

و کلاس های مورد نیاز را import می کنیم :

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;
import flash.geom.Point;

در مرحله بعد تابعی با نام blurApply ایجاد می کنیم و آرگمان آن را bmd و از نوع BitmapData قرار می دهیم.

function blurApply(bmd:BitmapData):BitmapData
{
	var effectBlur:BlurFilter = new BlurFilter(4,4,3);
	var rect:Rectangle = new Rectangle(0,0,bmd.width ,bmd.height );
	var point:Point = new Point(0,0);

	bmd.applyFilter(bmd , rect , point , effectBlur);

	return bmd;
}

در این تابع ابتدا یک متغیر با نام effectBlur می سازیم و نوع آن را BlurFilter قرار می دهیم و یک نمونه از کلاس BlurFilter را ایجاد می کنیم ، آرگمان های ورودی این کلاس سه مورد می باشد که دو مورد اول برای ایجاد افکت blur در طول و عرض می باشد و مورد سوم مربوطه به کیفیت این افکت که بر روی شی ما اعمال می شود.

در خط بعد ما یک متغیر از نوع Rectangle با نام rect ایجاد می کنیم ایم متغیر در واقع وظیفه مشخص کردن محدوده ای می باشد که قرار است افکت بر روی آن اعمال شود به همین دلیل دو مقدار اولیه که x, y می باشند و محل شروع را مشخص می کنند با ۰ و ۰ مقدار دهی شده اند و دو مقدار بعدی که مربوطه به عرض و طول می باشند با عرض و طول BitmapData که آرگمان ورودی این تابع می باشد مقدار دهی شده اند.

در خط بعد یک Point نیز با مقدار ۰,۰ ایجاد می کنیم که مشخص کننده گوشه سمت چپ و بالایی شی می باشد. به جای این بخش می توانیم از rect.topLeft نیز استفاده کنیم.

در خط بعد توسط applyFilter اقدام به اعمال افکت بر روی شی خود می نماییم، این متد مربوطه به BitmapData می باشد و آرگمان های ورودی آن به ترتیب مربوطه به شی BitmapData و محدوده مشخص کننده ، point و افکت تعریف شده ، می باشد.

تغییرات مورد نظر ما در این تابع بر روی bmd انجام شده است ، حال bmd را به عنوان مقدار بازگشتی تابع در خط آخر تابع return می کنیم.

تا این مرحله تابع مورد نظر ما ایجاد شد ، حال به نحوه استفاده آن می پردازیم. تصویری که در ابتدا در پروژه وارد کردیم را از stage حذف می کنیم به بخش Library می رویم و AS Linkage آن را با  MyPic مقدار دهی می کنیم.

حال یک متغیر با نام myPic و از نوع MyPic ایجاد می کنیم و آن را با یک نمونه از MyPic مقدار دهی می کنیم.

var myPic:MyPic = new MyPic();//دریافت تصویر از کتابخانه

سپس یک متغیر با نام bit می سازیم و آن را از نوع کلاس Bitmap قرار می دهیم و یک نمونه از کلاس Bitmap را به آن نسبت می دهیم در آرگمان اول مربوطه با کلاس Bitmap مقدار myPic را وارد می کنیم.

var bit:Bitmap = new Bitmap(myPic);

در مرحله بعد نیز خصوصیت BitmapData مربوطه به متغیر bit را توسط تابع ایجاد شده مقدار دهی می کنیم.

bit.bitmapData = blurApply(bit.bitmapData);
addChild(bit);

و در آخر نیز bit را توسط addChild به شی نمایشی (DisplayObject) اضافه می کنیم تا در صفحه نمایش داده شود.

نتیجه به این شکل خواهد بود :

حال اگر در تابع در بخش rect که مربوطه به محدوده ای می باشد که افکت بر روی آن اعمال می شود ، مقدارهای عرض و طول را تقسیم بر ۲ کنیم در واقع افکت بر روی یک چهارم تصویر اعمال می شود.

function blurApply(bmd:BitmapData):BitmapData
{
	var effectBlur:BlurFilter = new BlurFilter(4,4,3);
	var rect:Rectangle = new Rectangle(0,0,bmd.width/2 ,bmd.height/2 );
	var point:Point = new Point(0,0);

	bmd.applyFilter(bmd , rect , point , effectBlur);

	return bmd;
}

و نتیجه خروجی به این شکل خواهد بود :

شما این امکان را دارید که با مقدار دهی دو آرگمان اول rectangle در بخش نمایشی تصویر جا به جایی ایجاد کنید و توسط مقدار دهی دو آرگمان point مختصات محل نمایش بخشی که افکت بر روی آن اعمال شده را تغییر دهید.

در پایان تمام کدهایی که برای این پروژه نیاز می باشد را در زیر قرار می دهیم:

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Rectangle;
import flash.geom.Point;

function blurApply(bmd:BitmapData):BitmapData
{
	var effectBlur:BlurFilter = new BlurFilter(4,4,3);
	var rect:Rectangle = new Rectangle(0,0,bmd.width ,bmd.height);
	var point:Point = new Point(0,0);

	bmd.applyFilter(bmd , rect , point , effectBlur);

	return bmd;
}

var myPic:MyPic = new MyPic();//دریافت تصویر از کتابخانه
var bit:Bitmap = new Bitmap(myPic);

bit.bitmapData = blurApply(bit.bitmapData);
addChild(bit);

دانلود سورس : blur_effect_bitmapdata_iflashlord.zip 

تابعی که ما در این مطلب اقدام به ساخت آن می کنیم ، یک محتوای متنی را دریافت می کند و تمامی http:// و https:// های موجود دار آن را حذف می کند و در صورتی که آرگمان دوم آن که stripWWW می باشد برابر با true قرار داده شود تمامی www ها را نیز حذف می کند ، به طور پیش فرض ما این آرگمان را در تابعی که کد آن در زیر قرار داده شده است false قرار داده ایم.

برای بهتر متوجه شدن نتیجه این تابع به این مثال توجه کنید ، متن ورود ما که به عنوان آرگمان string در تابع تعریف شده است :

آخرین پروژه های اجرا شده را می توانید در http://www.iflashlord.com ببینید

متنی که بعد از استفاده این مقدار در تابع به عنوان آرگمان اول ، خروجی داده می شود به صورت زیر خواهد بود:

آخرین پروژه های اجرا شده را می توانید در www.iflashlord.com ببینید

و در صورتی که آرگمان دوم true باشد :

آخرین پروژه های اجرا شده را می توانید در iflashlord.com ببینید

حال به کد تابع می پردازیم:

function stripHttp(string:String, stripWWW:Boolean = false):String
{
	var s:String = string;
	var regexp:RegExp = new RegExp(! stripWWW ? "https*:\/\/":"https*:\/\/(www\.)*","ig");
	return s.replace(regexp, "");
}

بعد از تعریف تابع و آرگمان های آن ، یک متغییر برای ذخیره سازی کپی از متن ورودی در آن با نام s می سازیم ، سپس با کمک گرفتن از عبارات با قائده و تابع RegExp متغیر regexp را تعریف می کنیم ، این متغیر در واقع اشاره گری به تمامی http:// و https:// و www ها می باشد (در این مثال) و با استفاده از آن برای متد replace مربوطه به string ها و جا به جا کردن این مقادیر با مقدار “” که نشان گر مقدار پوچ می باشد ،این مقادیر را از رشته متنی خود حذف می کنیم

در نهایت رشته متنی نهایی که محتوای بازگشتی s.replace می باشد را توسط return بازگشت می دهیم.

برای استفاده از این تابع به شکل زیر اقدام می کنیم :

trace (stripHttp("آخرین پروژه های اجرا شده را می توانید در http://www.iflashlord.com ببینید" , true));
//آخرین پروژه های اجرا شده را می توانید در iflashlord.com ببینید

trace (stripHttp("آخرین پروژه های اجرا شده را می توانید در http://www.iflashlord.com ببینید" , false));
//آخرین پروژه های اجرا شده را می توانید در www.iflashlord.com ببینید

ویژگی پویایی، از جمله امکاناتی است که در گذشته در زبان اکشن اسکریپت وجود نداشت، اما از نسخه ۳ و FP9 به آن اضافه شد.

تنها تفاوت یک کلاس پویا، با کلاس غیر پویا در این است که کلاس پویا می‌تواند در زمان اجرا، صفات جدیدی را بپذیرد. در واقع به سادگی مقدار دهی به یک متغیر، می‌توان یک صفت جدید (property یا function یا حتی object) را به اشیائی که از یک کلاس پویا ایجاد شده‌اند اضافه نمود.

این تفاوت کوچک در عمل، کار و تعامل با کلاس‌های پویا را تا حد زیادی ساده می‌کند. از آنجا که شئ‌گرایی در AS 3.0 حد و مرز ندارد، در حین طراحی یک برنامه واقعی به دفعات اتفاق می‌افتد که بخواهیم صفات جدیدی را در زمان اجرا و تحت شرایطی خاص، به یک شئ اضافه نموده و یا از آن به عنوان یک حامل یا ظرف (Container) استفاده کنیم.

تعریف کلاس پویا:

package {
public dynamic class TestClass {
//defenition
}
}

اضافه کردن صفت در زمان اجرا:

var dynaObject: TestClass = new TestClass();

var obj:Object = new Object();
var idx:Array = new Array(1,2,3,4,5,6,7,8,9);

dynaObject.propTest = "newProperty";
dynaObject.obj = obj;
dynaObject["idx"] = idx;

trace(dynaObject.propTest, dynaObject.obj, dynaObject.idx);
//newProperty [object Object] 1,2,3,4,5,6,7,8,9

در استفاده از کلاس‌های پویا این دو نکته را به خاطر داشته باشید که:

- صفات پویا به instance اضافه می‌شوند نه خود کلاس.

- ویژگی پویایی در کلاس‌ها به ارث برده نمی‌شود.

توضیح: مقصود از “صفت” در AS 3.0، هم property و هم function یا method است.

+منبع

در این مطلب نحوه برقراری ارتباط با RSS یک وبسایت و دریافت اطلاعات آن به صورت XML آموزش داده می‌شود. بعد از دریافت اطلاعات به راحتی می‌توانید به کمک کدهای XML از این اطلاعات استفاده کنید.

۱- برای شروع لازم است که کلاسه‌های مورد نیاز را import کنید.

import flash.net.URLLoader;
import flash.events.Event;
import flash.net.URLRequest;

2- حالا یک متغیر از نوع URLLoader می‌سازیم، یک Event Listener برای آن تعریف می‌کنیم تا از کامل شدن دریافت اطلاعات آگاه شویم. سپس آدرس مورد نظر را Load می‌کنیم.

var loader:URLLoader = new URLLoader();
loader.addEventListener(Event.COMPLETE, loaded);
loader.load(new URLRequest("http://blog.iflashlord.com/feed/"));

3- در نهایت تابع loaded را که بعد از کامل شدن دریافت اطلاعات فراخوانی می‌شود، تعریف می‌کنیم.

function loaded(e:Event):void
{
	var xml:XML = XML(e.target.data);

	// Method 1:
	var xmlList:XMLList = xml.channel..item;

	// Method 2:
	//var xmlL:XMLList = xml.channel.elements("item");

	trace(xmlList.length());
	trace(xmlList[2]);
}

در این تابع:

• ابتدا اطلاعات دریافت شده به صورت XML تبدیل شده و در یک متغیر از نوع XML قرار می‌گیرند.
• در بین اطلاعات دریافت شده، element‌های item شامل اطلاعات هر پست هستند. برای جداسازی آنها از دو روش می‌توان استفاده کرد. بعد از جداسازی آنها را در یک متغیر از نوع XMLList ذخیره می‌کنیم.
• در نهایت نحوه استفاده از اطلاعات در دو مثال آمده است. (دستورات trace)

در این مطلب به slugify پرداخته می شود ، در کل به آماده کردن یک متن برای استفاده در URL و یا به عنوان نام یک فایل توسط حذف کاراکتر هایی که برای این موارد مجاز نمی باشد در استلاح slugify یا slug کردن نامیده می شود.

در ادامه ما توسط عبارات با قاعده (Regular-Expressions) و تابع replace در اکشن اسکریپت ۳ ، اقدام به ساخت تابعی می کنیم که این کار را برای ما انجام دهد.

در ابتدا دو RegExp که دو پترن مورد نیاز ما می باشند را به عنوان ثابت (const) تعریف می کنیم، مورد اول pattern1 مربوطه به انتخاب همه حروف الفبا و علامت دش (-) یا همان خط تیره می باشد که در کد زیر توسط (\ا-ی) تمامی حروف الفبای فارسی نیز پشتیبانی می شود، و مورد دوم pattern2 می باشد که فاصله ها یا همان Space های موجود در متن توسط آن انتخاب می شوند.

در نهایت توسط تابع replace مربوطه به string ها در اکشن اسکریپت ۳ متون اضافی حذف  ،و فاصله ها با علامت (-) جا به جا می شوند و در نهایت متن توسط toLowerCase به حروف کوچک تبدیل می شود و بازگشت داده می شود.

function slugify(string:String):String
{
const pattern1:RegExp = /[^\w-\ا-ی ]/g;// همه حروف به جز فاصله و علامت دش (-) ؛
const pattern2:RegExp = / +/g;// یک یا بیش از یک فاصله
var s:String = string;
return s.replace(pattern1, "").replace(pattern2, "-").toLowerCase();
}
//مثال
trace(slugify("تست  متن با فاصله"));
//تست-متن-با-فاصله

trace(slugify("test  text with space"));
//test-text-with-space

اگر می خواهید که تنها کاراکتر های انگلیسی پشتیبانی شود و متون فارسی نیز از خروجی حدف شود تابع بالا را طبق کد زیر تغییر دهید:

function slugify(string:String):String
{
const pattern1:RegExp = /[^\w- ]/g;// همه حروف انگلیسی به جز فاصله و علامت دش (-) ؛
const pattern2:RegExp = / +/g;// یک یا بیش از یک فاصله
var s:String = string;
return s.replace(pattern1, "").replace(pattern2, "-").toLowerCase();
}
//مثال
trace(slugify("تست  متن با فاصله"));//-
trace(slugify("test  text with space"));//test-text-with-space

این تابع در مواردی که می خواهید متون را در آدرس های وب (URL) و یا به عنوان نام فایل مورد استفاده قرار دهید ،کاربرد دارد.

بهینه سازی در فلش یک اصل مهم به حساب می آید و افزایش و کار بر روی آن برای توسعه دهندگان فلش امری الزامی است. به عنوان یک توسعه دهنده فلش و به عنوان کسی که برای آینده این نرم افزار بزرگ احساس مسئولیت می کند ، ما وظیفه داریم در ساخت عناصر فلش که کارایی بهتری دارند پیش گام باشیم و همواره بهترین و بهینه ترین روش را استفاده کنیم. در این مجموعه آموزشی بهینه سازی فلش به نکات مهم برای مدیریت بر عناصر و حافظه ها … می پردازیم و تلاش می کنیم که بتوانیم با استفاده از نکات ارائه شده خروجی بهینه تر و سبک تری از پروژه فلش خود داشته باشیم.

بخش چهارم – فعال سازی(Activate) و غیر فعال سازی(Deactivate) رویدادها

از زمان انتشار فلش پلیر ۹ (Flash Player 9) دو رویداد (Event) به فلش افزوده شد (رویداد Event.ACTIVATE و رویداد Event.DEACTIVATE) این رویداد ها می توانند برای شما امکان تنظیم برنامه خود برای استفاده از کمترین میزان سیکل پردازنده (CPU) را امکان پذیر سازند.

این رویداد ها این امکان را به شما می دهند که زمانی که روی فلش شما تمرکز (فوکوس) می شود و یا زمانی که تمرکز (فوکوس) از روی آن خارج می شود را تشخیص دهید. در نتیجه ، می توان کد را برای نشان دادن واکنش به تغییرات فعال و غیر فعال شدن بهینه سازی نمود.

نکته : استفاده از رویدادهای Event.ACTIVATE و Event.DEACTIVATE برای تشخص عدم فعالیت برنامه ای که در پس زمینه کاری قرار دارد و بهینه سازی برنامه شما مناسب می باشد.

در کد زیر از هر دو رویداد استفاده می کنیم و به صورت پویا نرخ فریم (Frame rate) را در زمانی که فوکوس (Focus) از برنامه خارج شود روی صفر تنظیم می کنیم. به عنوان مثال زمانی که شما به تب دیگر از مرورگر می روید و یا خارج از محیط قرار گیری فلش در صفحه کلیک می کنید و یا برنامه را در پس زمینه کاری قرار می دهید برنامه شما از فوکوس خارج می شود.

//تعریف متغییر نرخ فریم جاری و نرخ فریم حالت غیر فعال
var originalFrameRate:uint = stage.frameRate;
var standbyFrameRate:uint = 0;

stage.addEventListener( Event.ACTIVATE, onActivate );
stage.addEventListener( Event.DEACTIVATE, onDeactivate );

function onActivate( e:Event ):void
{
	// بازگرداندن نرخ فریم اصلی
	stage.frameRate = originalFrameRate;
}

function onDeactivate( e:Event ):void
{
	// تنظیم نرخ فریم بر روی صفر
	stage.frameRate = standbyFrameRate;
}

زمانی که روی برنامه شما دوباره فوکوس می شود ، نرخ فریم به حالت اصلی بازگردانده می شود و برنامه شما به کارش ادامه می دهد. در ضمن شما به جای استفاده از تغییر نرخ فریم به صورت پویا می توانید بهینه سازی های دیگر مانند فریز کردن اشاء ، دادن افکت بلور و… را درون برنامه خود در نظر بگیرید.

این رویداد ها به شما این امکان را می دهد که مکانیزمی شبیه به Pause و Resume که در واقع امکان ایجاد مکث و وقفه در برنامه و امکان ادامه دادن آن در زمان دلخواه می باشد را ایجاد کنید. نمونه ی این ویژگی را شاید گاهی اوقات در برنامه های تلفن های همراه و یا نت بوک های دیده باشید ، شما هم می توانید به برنامه خود اینچنین امکانی را اضافه کنید.

موفق و پیروز باشید.

همان طور که می دانید یکی از مواردی که برای بحث ثبت نام کاربران وجود دارد و در مواردی بسیار مهم است ، انتخاب رمز عبور امن می باشد ، با توجه به این که یک رمز عبور امن شرایط خاصی را دارد ، این تابع به شما کمک می کند در هنگامی که کاربر در حال وارد کردن نام کاربر و رمز عبور است با توجه به این دو مقدار که به عنوان آرگمان های ورودی تابع وارد می شوند سطح امنیت و استحکام مربوطه به رمز عبور انتخاب شده را مشخص کنید
و به کاربر اطلاع دهید در حال انتخاب رمز عبور با چه امنیت و استحکامی می باشد ، این مورد برای کاربرانی که از اهمیت انتخاب رمز عبور مناسب برای جلوگیری از هک شدن و قابل حدس بودن رمز عبور وارد شده ، اطلاعات کافی ندارند ، مناسب می باشد.

همان طور که در اکثر موارد مثل هاستینگ ها و مواردی که امنیت برای آنها مهم هست این مورد را دیده اید.

در کد زیر نمونه هایی هم برای تست رمزهای عبور با استحکام بالا و پایین زده شده است.
در حال حاضر این تابع ۳ سطح را مشخص می کند که عبارتند از Strong که نشانه استحکام و امنیت بالا می باشد ، Medium که استحکام و امنیت متوسط را نشان می دهد ، Weak که استحکام و امنیت پایین را نشان می دهد.

trace(StrengthMeter("iflashlord.com" , "#$_-+f@wa2Q1"));//Strong
trace(StrengthMeter("iflashlord.com" , "12345"));//Weak
trace(StrengthMeter("iflashlord.com" , "iflashlord.com"));//Weak
trace(StrengthMeter("iflashlord.com" , "IFLashLord.com"));//Medium
trace(StrengthMeter("iflashlord.com" , "24fd"));//Weak
trace(StrengthMeter("iflashlord.com" , "24fd3"));//Medium

//iflashlord.com - StrengthMeter Pro - 19-02-2011
function StrengthMeter(vUserName : String,vPassword : String):String
{
	var vScore:int = 0;
	var vHasLetters:Array = vPassword.match(/[a-zA-Z]+/);
	var vHasNumbers:Array = vPassword.match(/[0-9]+/g);
	var vHasPunctuation:Array = vPassword.match(/[^a-zA-Z0-9]+/);
	var vHasCasing:Array = vPassword.match(/[a-z]+.*[A-Z]+|[A-Z]+.*[a-z]+/);
	var vResult:String;

	if (vPassword.length == 0)
	{
		return "It's blank!";
	}

	vScore += (vPassword.length < 7 ? 0 : 1);
	vScore += (vPassword.length >= 12 ? 1 : 0);
	vScore += (vPassword.toLowerCase() == vUserName.toLowerCase() ? 0 : 1);
	vScore += ((vHasNumbers == null || vHasNumbers.length==0 ) ? 0 : 1);
	vScore += (vHasNumbers != null && vHasNumbers.length <= 4 ? 0 : 1);
	vScore += ((vHasPunctuation == null || vHasPunctuation.length == 0) ? 0 : 1);
	vScore += (vHasPunctuation != null && String(vHasPunctuation).length <= 2 ? 0 : 1);
	vScore += (vHasCasing == null ? 0 : 1);
	vScore += (vHasCasing != null && String(vHasCasing).length <= 2 ? 0 : 1);

	vScore -= ((vHasLetters == null || vHasLetters.length==0 ) ? 1 : 0);
	vScore -= (vPassword == vUserName ? 1 : 0);
	vScore -= (vPassword.length <= 4 ? 1 : 0);

	switch (vScore)
	{
		case -3 :
		case -2 :
		case -1 :
		case 0 :
		case 1 :
		case 2 :
		case 3 :
			vResult = "Weak";
			break;
		case 4 :
		case 5 :
		case 6 :
		case 7 :
			vResult = "Medium";
			break;
		case 8 :
		case 9 :
			vResult = "Strong";
			break;
	}
	return vResult;
}

در این تابع سعی شده مهم ترین موارد مد نظر قرار داده شود تا با دقت هر چه بیشتر این محاسبه انجام شود.

آیا شما نظری برای بهبود دقت و عملکرد این تابع دارید؟

این مطلب یکی از مجموعه آموزش های کوتاهی می باشد که از این به بعد مطالبی دیگر نیز با این سبک خواهیم داشت ، به صورت کوتاه به نکته ای کاربردی و مهم پرداخته می شود ، امیدوارم مورد توجه دوستداران فلش و اکشن اسکریپت قرار بگیرد.

توسط کدی که در پایان مطلب قرار داده شده است می توانیم وقفه زمانی در پخش Movie فلش در بخشی (فریمی) از تایم لاین (TimeLine) ایجاد کنیم.

این کد توسط تابع تعریف شده با نام wait بعد از فراخوانی در هر فریم از تایم لاین Movie حرکت را stop می کند (خط ۵) و بلافاصله با تعریف کلاس  Timer با توجه به مقداری که به عنوان آرگمان ورودی wait وارد شده است (خط ۶) (این آرگمان بر مبنای millisecond می باشد ، به این معنا که ۱۰۰۰ برابر ۱ ثانیه است) ، رویدادی ایجاد می کند (خط ۷) که بعد از اتمام زمان وارد شده تابع continuePlayhead را فراخوانی می کند ، که با اجرای فرمان play ادامه پخش Movie انجام می شود (خط ۱۳)، بعد در مرحله اول تایمر stop می شود (خط ۱۴)و بعد تایمر reset می شود (خط ۱۵) (این امر برای بدون مشکل بودن استفاده های بعدی می باشد) و رویدادی که تایمر ایجاد شده بود نیز در این مرحله حذف می گردد (خط ۱۶).

نکته : متغییر delayTimer که از نوع Timer می باشد در ابتدا و خارج از توابع تعریف شده است که دسترسی به آن در هر دو تابع وجود داشته باشد.

var delayTimer:Timer;

function wait(timeToHold:Number)
{
	stop();
	delayTimer = new Timer(timeToHold,0);
	delayTimer.addEventListener(TimerEvent.TIMER, continuePlayahead);
	delayTimer.start();
}

function continuePlayahead(e:Event):void
{
	play();
	delayTimer.stop();
	delayTimer.reset();
	delayTimer.removeEventListener(TimerEvent.TIMER, continuePlayahead);
}

به نظر شما این روش ، روش مناسبی برای ایجاد وقفه زمانی در تایم لاین می باشد؟
آیا روش دیگری برای این کار می شناسید؟

یکی از مواردی که در برنامه نویسی اکشن اسکریپت جایگاه مهمی دارد ، توابع می باشند. به طوری که نسخه جدید فلش بر پایه توابع نوشته شده است. مثالا شما بعد از تعیین رویدادی برای دکمه ای می بایست این رویداد را به تابعی ارسال نمایید تا دسترسی های رویداد را توسط آن کنترل نمایید ( در زمان وقوع رویداد)
به همین دلیل سعی می کنیم با توابع و قواعد آن به صورتی سطحی آشنایی پیدا کنیم :

در این مطلب به موارد زیر می پردازیم :

۱. تابع چیست ؟
۲. مثالی در مورد کاربرد تابع.
۳. توضیحات ساده در مورد تابع.
۴. توضیحات پیشرفته در مورد تابع.

تابع چیست ؟
اصولا توابع یک بلاک (بخش) از کد هستند که به عنوان تابع ایجاد می شوند و ما می توانید با تعریف تنها یک باره آنها ، آنها را در موارد متعدد مورد استفاده قرار دهیم و هم در حجم و هم در سرعت فراخوانی و هم در تمیزی و قابل فهم تر بودن کدی که می نویسم بسیار تاثیر گزار می باشد.
یکی دیگر از فواید توابع این می باشد که شما در هر زمان می تواند کد مربوط به تابع خود را به روز رسانی نمایید و دیگر نیازی نیست که کدها را در تمامی بخش های استفاده شده تغییر دهید.
در ادامه با مثال بیشتر با توابع آشنا خواهید شد.

مثالی در مورد کاربرد تابع:

به کد زیر دقت نمایید ، توسط این کد ما شی Star را از درون کتابخانه فلش با مختصات x و y ی که تعریف می کنیم به استیج پروژه اضافه می کنیم

var myStar:Star;

myStar = new Star();
myStar.x = 100;
myStar.y = 150;
addChild(myStar);

توجه : کلاسStar یک MovieClip می باشد که ما آن را با Star در Library نام گزاری کرده ایم و یک کلاس ثابت از مجموعه کلاس های نرم افزار فلش نمی باشد.

خوب حال به فرض ما نیاز داریم این شی را و یا شی دیگری را در جایی دیگر از صفحه و یا در همان مختصات دوباره اضافه کنیم ، برای این کار می بایست کد را دوبار تکرار کنیم!!!

var myStar:Star;

myStar = new Star();
myStar.x = 100;
myStar.y = 150;
addChild(myStar);

myStar = new Square();
myStar.x = 100;
myStar.y = 150;
addChild(myStar);

این کار در عمل مشکلی ندارد ولی باعث می شود کد پروژه شما بسیار حجیم و زیاد بشود در زمان ویرایش و … دچار مشکلات و سختی فراوان بشوید خوب حال همین کد را با کمک توابه می توانیم به صورت زیر استفاده کنیم :

function makeStar():void {
	myStar = new Star();
	myStar.x = 100;
	myStar.y = 150;
	addChild(myStar);
}

makeStar();
makeStar();

هر چند بار که بخواهیم می توانیم makeStar را فراخوانی کرده و با هر بار فراخوانی تمامی کدهای درون تابع را اجرا کنیم.

توضیحات ساده در مورد تابع:

ساختار کلی تابع به صورت زیر می باشد :

function functionName(argument):returnType{
	statements;
}

توضیحات ساختاری :

functionName : نام تابع می باشد که که توسط آن شما می توانید تابع را فراخوانی نمایید.
argument : یا آرگومان های تابع ورودی های تابع می باشند که با کاما از هم جدا می شوند (در ادامه با مثال توضیح بیشتر داده می شود)

returnType : نوع بازگشت تابع می باشد، در واقع برای تعیین نوع مقداری که قرار است درون تابع return شود در صورتی که تابع شما return ی نداشته باشد این مقدار بر روی void قرار می دهیم و این به این معنی می باشد که تابع مقداری را بر نمی گرداند، البته تعریف این مقدار الزامی نیست و در صورتی که نوع خروجی را ندانید می توانید با ستاره(*) به هر نوعی از اطلاعات اشاره نمایید.

statements : شامل کدی می شود که می بایست با هر بار فراخوانی تابع اجرا شود.

حال تابعی ایجاد می کنیم که یک MovieClip ایجاد نماید و آن را در مختصات x و y مقدار دهی نماید
توجه داشته باشید که کد مربوط به تابع می بایست بین دو براکت {} مربوط به تابع قرار گیرد و نکته دیگر این است که متغیری که درون تابعی تعریف شود از بیرون تابع یعنی بیرون محدوده {} تابع قابل فراخوانی نیست. (در ادامه توضحاتی در این مورد داده شده)

به مثال دقت بفرمایید :

function magicalFunction(){
	var myMovie:MovieClip = new MovieClip();
	myMovie.x=100;
	myMovie.y=150;
}

در بالا تابعی با نام magicalFunction ایجاد کردیم.
و حال برای فراخوانی تابع باید به این نکته توجه داشته باشیم که برای فراخوانی تابع صورت مجزا و نه درون رویدادها می بایست از دوپرانتز در آخر نام تابع استفاده کنیم ، این () در واقع محل آرگومان های تابع می باشد و در صورتی که تابع آرگمانی نداشته باشد به صورت زیر استفاده می شود.

فراخوانی ساده :

magicalFunction();

فراخوانی در رویداد :

addEventListener(MouseEvent.CLICK ,magicalFunction );

باید توجه داشته باشید تا زمانی که تابع فراخوانی نشود(با کدهای بالا) کد تابع اجرا نخواهد شد.

توضیحات پیشرفته در مورد تابع:

همان گونه که در مرحله قبل ذکر کردیم ساختار تابع به شکل زیر می باشد :

function functionName(argument):returnType{
	statements;
}

حال می خواهیم به arguments و با همان آرگمان های تابع بپرداریم ، توجه داشته باشد که بهتر است نوع هر آرگمان را مشخص کنید که مثلا عددی است و یا رشته متنی و…
نکته دیگر این است که آرگمان ها با کاما (,) از هم جدا می شوند و به تعداد نامحدود شما می توانید آرگمان داشته باشید
شما آرگمان خود را با نامی در () بعد از نام تابع تعریف می کنید و با همین نام می توانید از آن در تابع خود استفاده کنید ، در زمان فراخوانی تابع این آرگمان ها مقدار دهی می شود و مقدارها درون کد تابع مورد استفاده قرار می گیرد.

کدی که در قبل استفاده کردیم امکان مقدار دهی به x و y را در زمان فراخوانی را ندارد!!

 var myStar:Star;

function makeStar():void {
	myStar = new Star();
	myStar.x = 100;
	myStar.y = 150;
	addChild(myStar);
}

makeStar();
makeStar();

حال کد را طبق تعاریفی که در بالا داشتیم به صورت زیر تغییر می دهیم :

var myStar:Star;

function makeStar(myX:Number, myY:Number):void {
	myStar = new Star();
	myStar.x = myX;
	myStar.y = myY;
	addChild(myStar);
}

makeStar(100,200);
makeStar(150,320);

همان طور که در کد مشاهده می کنید دو آرگمان myX:Number, myY:Number را تعریف کردیم و همین متغیرها را در کد به جای مقدارهای عددی قرار دادیم.

حال در زمان فراخوانی به راحتی می توانیم مختصات را نیز تعریف نماییم. در کد بالا ستاره اول در مختصات ۱۰۰,۲۰۰ و ستاره دوم در مختصات ۱۵۰,۳۲۰ ایجاد می شود.

برای درک بیشتر return تابعی تعریف می کنیم که دو قدار را جمع کند و یک مقدار به عنوان خروجی بدهد:

function calculate(){
	var num1:Number = 50;
	var num2:Number = 100;
	var myResult:Number;

	myResult = num1+num2;
	return myResult;
}

و حال توسط کد زیر از آن استفاده می کنیم :

var myMC:MovieClip = new MovieClip();
myMC.x = calculate();

با این کار مختصات x مریوط به myMC به مقدار ۱۵۰ که جمع دو عددی که در تابع بود ، می باشد مقدار دهی می شود زیرا تابع calculate مقداری را که با return بر می گرداند مثل این است که ما myMC.x را برابر ۱۵۰ قرار داده باشیم.

در مثال بالا خروجی تابع مقداری عددی است پس بهتر است خروجی با Number مقدار دهی شود و کد را به صورت زیر بنویسیم:

function calculate():Number{
	var num1:Number = 50;
	var num2:Number = 100;
	var myResult:Number;

	myResult = num1+num2;
	return myResult;
}

var myMC:MovieClip = new MovieClip();
myMC.x = calculate();

همان طور که برای تابع makeStar نوع داده بازگشتی را بر روی void به این معنی که بازگشتی ندارد قرار دادیم

به صورت کلی تابعی که بازگشتی نداشته باشد و return در آن استفاده نشده باشد را با void تعیین می کنیم و در صورتی که نوع بازگشت نوعی ثابت و خاصی نباشد آن را با * تعیین می کنیم

نکته دیگر در مورد توابع دسترسی به متغییر های داخل توابع می باشد که به صورت عادی امکان پذیر نمی باشد

به طور مثال کد زیر با خطا رو به رو خواهد شد :

function calculate ():Number {

	var num1:Number = 50;
	var num2:Number = 100;
	var myResult:Number;
	myResult = num1+num2;

}

trace(myResult);

زیرا myResult قابل دسترسی از خارج تابع نمی باشد

برای حل این مشکل از روش زیر استفاده می کنیم و کد را به صورت زیر می نویسیم :

var myResult:Number;

function calculate ():Number {

	var num1:Number = 50;
	var num2:Number = 100;
	myResult = num1+num2;

}

trace(myResult);

تنها کاری که انجام دادیم این بود که متغییر myResult را خارج از محل تابع تعریف کردیم و درون تابع فقط مقدار دهی را انجام دادیم
این موضوع در مورد حلقه ها هم یک بار توضیح داده شده است.

آرگمان نامحدود برای تابع (استفاده از امکان (…) در تابع):

این موضوع یک بحث جدید در مورد توابع می باشد که با یک مثال آن را توضیح می دهیم ، گاهی اوقات ما نیاز داریم تابع ما به تعداد نامحدودی آرگمان ورودی بپزید و تعداد ورودی را دقیق نمی دانیم تا برا آن مقداری را تعریف کنیم ، یک را این است که مقدارها را به صورت آرایه به تابع بدهیم و راه جدید در واقع ساده شده همان راه دادن داده ها به صورت تابع می باشد (با کمک تکنیک سه نقطه (…) )

به کد مربوطه دقت نمایید :

function Sum (...arg:Array):Number {
	var sumNum:Number=0;
	for(var i:Number = 0; i<arg.length; ++i) {
		sumNum +=arg[i];
	}
	return sumNum;
}

trace(Sum (2,2,3));

در بالا ابتدا تابعی با نام Sum ایجاد می کنیم و برای آرگمان های آن قبل از نام آرگمان … اضافه می کنیم و بدون فاصله نام آرگمان خود را که در اینجا arg می باشد نام می نویسم و نوع آن را هم با : بر روی آرایه Array تنظیم می کنیم
در این مثال خروجی ما از نوع عددی می باشد ( در واقع این تابع تمامی آرگمانهایی که به عنوان ورودی به آن داده شود را با هم جمع می کند )
حال ما در تابع آرایه ای با مقدار تمامی آرگمان های ورودی تابع مربوطه داریم که با یک for و پیمایش تابع مقدارها را توسط += به sumNum می دهیم و مقدار آن را با تمامی عناصر آرایه ورودی ها اضافه می کنیم و در آخر توسط return مقدار sumNum را به عنوان خروجی تعیین می کنیم

در آخر بعد از تکمیل تابع برای تست خروجی از تابع trace استفاده می کنیم و نتیجه جمع اعدادی که وارد کرده ایم را در Output نمایش می دهیم.

مقادیر و امکانات زیادی برای توابع وجود دارد ، برای اطلاعات بیشتر به راهنمای فلش مراجعه نمایید