در این مطلب نحوه فشرده سازی فایل‌ها به صورت zip و استخراج فایل‌های فشرده شده با فرمت zip و نمایش لیست محتویات فایل zip آموزش داده می‌شود. همچنین در این درس استفاده از کلاسه‌های swc آموزش داده می‌شود.

دانلود : components.zip | source_extract_zip_list.zip

قبل از شروع فایل components.zip را دانلود کنید و فایل‌های داخل آنرا با توجه به محل نصب Flash در پوشه libs کپی کنید.

install Path:
\Adobe\Adobe Flash CS5\Common\Configuration\ActionScript 3.0\libs

فشرده سازی فایل‌ها

۱- برنامه Flash را اجرا کنید.

۲-  یک پروژه جدید Air ایجاد کنید.

۳- حال کلاسه‌های مورد نظر را import کنید.

import deng.fzip.*;
import deng.utils.ChecksumUtil;
import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.filesystem.FileStream;
import flash.filesystem.FileMode;

4- در ادامه باید ۳ متغیر ایجاد کنید و فایل مورد نظر را که می‌خواهید فشرده شود تعریف نمایید.

var zip:FZip = new FZip();
var ba:ByteArray = new ByteArray();
var file:File = new File();

5- با کد resolvePath فایل مورد نظر را به کلاسه File معرفی کنید. (به جای c:/test.txt آدرس فایل مورد نظرتان را بنویسید. دقت کنید که به جای “\” از “/” استفاده نمایید.)

file = file.resolvePath("c:/test.txt");

6- حال باید فایل مورد نظر و محتویات آنرا به متغیر zip معرفی کنید. همچنین واسطه ByteArray را هم باید به zip معرفی کنید.

zip.addFile(file.name,file.data);
zip.serialize(ba);
ba.position = 0;

7- در نهایت نیاز است که آدرس فایل خروجی (با فرمت zip) را تعریف کرده و به وسیله یک FileStream اطلاعات تبدیل شده را روی آن دخیره کرد.

var finalZip:File = File.desktopDirectory.resolvePath(“test.zip”);
var fs:FileStream = new FileStream();
fs.open(finalZip,FileMode.WRITE);
fs.writeBytes(ba);
fs.close();

استخراج فایل Zip

1- یک پروژه جدید Air ایجاد کنید.

۲- از منوی Window پنل Components را فعال کنید.

۳- از دسته User Interface گزینه Button را انتخاب کنید و ۲ بار آنرا به داخل صفحه Drag کنید.

۴- در پنل Properties، نام Instance دکمه‌ها را به ترتیب load_btn و extract بگذارید و تنظیمات مربوطه را به صورت زیر انجام دهید.

۵- حال کلاسه‌های مورد نظر را import کنید و متغیرهای مورد نیاز را برای تعریف فایل zip ایجاد کنید.

import flash.filesystem.*;
import flash.net.FileFilter;
import nochump.util.zip.*;
import flash.events.Event;
var zipInput:File = new File();
var zipOutput:File = new File();
var zipFile:ZipFile;

6- در ادامه برای هر دکمه یک Event Listener تعریف کنید تا در هر بار کلیک توابع مربوطه اجرا شود.

load_btn.addEventListener("click", loadZIP);
extract.addEventListener("click", extractZIP);

7- تابع loadZip را که بعد از کلیک روی دکمه load_btn فراخوانی می‌شود، به صورت زیر تعریف کنید. بعد از کلیک روی این دکمه یک پنجره برای انتخاب فایل zip اجرا می‌شود.

function loadZIP(e:Event):void
{
	var filter:FileFilter = new FileFilter("ZIP","*.zip");
	zipInput.browseForOpen("Open ZIP file",[filter]);
	zipInput.addEventListener(Event.SELECT, onSelect);
}

اجزای مختلف این تابع به صورت زیر است:

• filter: یک متغیر از نوع FileFilter برای تعریف فرمت Zip که بعد از کلیک روی دکمه مربوطه در پنجره انتخاب فایل نمایش داده می‌شود.
• browseForOpen: پنجره انتخاب فایل را نشان می‌دهد و عنوان آن در اینجا برای مثال “Open Zip file” و فرمت فایل‌های انتخابی filter می‌باشد.

۸- حال باید تابع onSelect را که بعد از انتخاب فایل فراخوانی می‌شود، تعریف کنید.

function onSelect(e:Event):void
{
	var stream:FileStream = new FileStream();
	stream.open(zipInput,FileMode.READ);
	zipFile = new ZipFile(stream);
	extract.enabled = true;
}

در این تابع:

• stream: متغیری از نوع FileStream است که فایل zip انتخاب شده را در برنامه به جریان می‌اندازد.
• zipFile: متغیری است که در ابتدا ایجاد شد و در اینجا stream به آن معرفی می‌شود.

۹- تابع extractZIP که بعد از کلیک روی دکمه extract فراخوانی می‌شود، به صورت زیر تعریف می‌شود. در این تابع یک پنجره برای انتخاب پوشه مقصد (جایی که فایل zip باید استخراج شود) نمایش داده می‌شود.

function extractZIP(e:Event):void
{
	zipOutput.browseForDirectory("Select Directory for extract");
	zipOutput.addEventListener(Event.SELECT, onDirSelect);
}

10- درنهایت تابع onDirSelect را که بعد از انتخاب پوشه مقصد فراخوانی می‌شود، به صورت زیر تعریف کنید.

function onDirSelect(e:Event):void
{
	for (var i:uint = 0; i<zipFile.entries.length; i++)
	{
		var zipEntry:ZipEntry = zipFile.entries[i] as ZipEntry;
		if (! zipEntry.isDirectory())
		{
			var targetDir:File = e.target as File;
			var entryFile:File = new File();
			entryFile = targetDir.resolvePath(zipEntry.name);
			var entry:FileStream = new FileStream();
			entry.open(entryFile, FileMode.WRITE);
			entry.writeBytes(zipFile.getInput(zipEntry));
			entry.close();
		}
		trace("Finished.");
	}
}

در این تابع:

• یک حلقه for ایجاد شده است که به تعداد فایل‌های داخل فایل zip تکرار می‌شود.
• در داخل حلقه یک متغیر از نوع ZipEntry تعریف شده است که محتویات فایل zip را یکی یکی معرفی می‌کند.
• همچنین در داخل حلقه، یک دستور if وجود دارد که مطمئن می‌شود، فایل ورودی از zipEntry یک پوشه نباشد.
• در ادامه فایل ورودی به وسیله یک FileStream در پوشه مقصد ذخیره می‌شود.
• در نهایت بعد از تکمیل استخراج فایل zip، عبارت Finished نشان داده می‌شود.

نمایش فهرست فایل‌های داخل Zip

با استفاده از کلاسه‌های swc نصب شده در ابتدای این درس می‌توانید فهرست فایل ‌های داخل Zip را نمایش دهید. بدین منظور از کدهای زیر استفاده کنید.

import deng.fzip.*;
import deng.utils.ChecksumUtil;
import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.events.Event;
import flash.net.URLRequest;

var zip:FZip = new FZip();
zip.addEventListener(FZipEvent.FILE_LOADED, fileLoaded);
zip.load(new URLRequest("d:/test.zip"));

function fileLoaded(e:FZipEvent):void
{
	var file:FZipFile = e.file;
	trace("File Loaded: " + file.filename);
	trace(" " + file.sizeCompressed);
	trace(" " + file.sizeUncompressed);
}

در این مطلب نحوه اتصال به یک Web Service و دریافت اطلاعات آن توسط برنامه Air آموزش داده می‌شود. برای این کار از کلاسه‌های Flex در پروژه Flash استفاده خواهد شد. برای مثال در این درس درجه حرارت سلسیوس را به کمک Web Service به درجه فارنهایت تبدیل می‌کنیم.

دانلود سورس : source.zip

1- برنامه Flash را اجرا کنید و یک پروژه از نوع Air بسازید.

۲- از منوی File گزینه ActionScript Settings را انتخاب کنید.

۳- وارد بخش Library Path شوید و روی دکمه Browse To Path کلیک کنید.

۴- حالا پوشه libs را با توجه به آدرس و نسخه نصب شده برنامه Adobe Flash Builder انتخاب کنید. برای مثال:

(Install Path:)\Adobe\Adobe Flash Builder 4\sdks\4.0.0\frameworks\libs

5- بعد از انتخاب این آدرس در پایین پنجره ActionScript Settings وضعیت Default linkage را روی Merged into code قرار دهید.

۶- روی OK کلیک کنید تا کلاسه Flex در پروژه تعریف شود.

۷- حالا از پنل Components و با استفاده از شاخه User Interface یک Button، دو Text Input و دو Label به داخل صفحه Drag کنید و یک فرم شبیه فرم زیر بسازید.

۸- در ادامه تنظیمات این Component‌ها را به صورت زیر تغییر دهید.

۹- حالا روی فریم اول کلیک کنید و پنل Actions را باز کنید.

۱۰- در ابتدا لازمه که کلاسه‌های مورد نیاز را Import کنید.

import flash.display.MovieClip;
import flash.events.MouseEvent;
import mx.rpc.soap.*;
import mx.rpc.events.*;

11- حالا یک متغیر WebService ایجاد می‌کنیم.

var webService:WebService;

12- در این آموزش بعد از کلیک روی دکمه convert اطلاعات فیلد متنی درجه سلسیوس به Web Service فرستاده می‌شود و سپس اطلاعات دریافتی از Web Service در فیلد متنی درجه فارنهایت نشان داده می‌شود. پس یک Event Listener برای دکمه تعریف می‌کنیم.

startButton.addEventListener(MouseEvent.CLICK, SetupWebService);

13- برای ادامه باید تابع SetupWebService را تعریف کنیم که بعد از کلیک روی دکمه convert فراخوانی می‌شود.

function SetupWebService(event:MouseEvent):void
{
	webService = new WebService();
	webService.loadWSDL("http://www.w3schools.com/webservices/tempconvert.asmx?WSDL");
	webService.addEventListener(LoadEvent.LOAD, BuildServiceRequest);
}

در این تابع:

• لینک http://www.w3schools.com/webservices/tempconvert.asmx فراخوانی می‌شود. به جای این آدرس می‌توانید از هر آدرس دیگری استفاده کنید. دستور ?WSDL این آدرس را به صورت XML تعریف می‌کند تا در Flash قابل استفاده باشد.
• بعد از Load شدن محتویات لینک با تعریف یک Event Listener برای webService تابع BuildServiceRequest فراخوانی می‌شود.

function BuildServiceRequest(evt:LoadEvent)
{
	webService.CelsiusToFahrenheit(c.text);
	webService.CelsiusToFahrenheit.addEventListener(ResultEvent .RESULT, onResult);
	webService.CelsiusToFahrenheit.addEventListener(FaultEvent. FAULT, onFault);
}

در این تابع:

• اطلاعات فیلد متنی سلسیوس (c.text) به اپراتور CelsiusToFahrenheit که در لینک Web Service قابل مشاهده است، فرستاده می‌شود.
• دو Event Listener برای webService تعریف شده است که اولی بعد از کامل شدن عملیات و دومی‌درصورت بروز خطا فراخوانی می‌شوند.

function onResult(event:ResultEvent)
{
	f.text = String(event.result);
}

function onFault(event:FaultEvent)
{
	trace("error");
	trace(event.fault.getStackTrace());
}

در تابع onResult:

• اطلاعات دریافتی از Web Service در فیلد متنی فارنهایت نمایش داده می‌شود.

در تابع onFault:

• خطای به وجود آمده در فرایند ارسال و دریافت اطلاعات نمایش داده می‌شود.

با توجه به این که شاید پروژه نهایی ارائه شده در بخش سوم این آموزش کامل نمی باشد ، سعی می کنیم در این بخش از آموزش نکات ریزی که ممکن هست در کار با صدا ها و مثال های ذکر شده در آموزش قبل به آنها بر بخورید را در این مطلب توضیح دهیم  :

موردی که در آموزش قبلی احتمالا به آن بر خورده اید ، پخش چند باره با کلیک مجدد بر روی دکمه Play می باشد که این امر به دلیل عدم چک کردن در حال پخش بودن می باشد ، ما در این بخش با ایجاد variable ی با نام isPlay از نوع Boolean و مقدار دهی اولیه true به آن می توانیم با مقدار دهی این متغییر در طول برنامه و با شرطی ساده در تابع مربوز به پخش صدا جلوی پخش مجدد را بگیریم.

function onClickPlay(e:MouseEvent)
{
	if (! isPlay)
	{
		myChannel = mySound.play(lastPosition);
		myChannel.soundTransform = myTransform;
		isPlay = true;
	}
}

مورد بعدی برای مواردی که شما نیاز دارید دکمه Stop را هم به همراه Pause و Play داشته باشید که برای این مورد هم در کد زیر بدون حذف این مورد می توانید مشاهده نمایید.

function onClickStop(e:MouseEvent):void
{
	myChannel.stop();
	lastPosition = 0;
	isPlay = false;
}

مورد بعدی برای افرادی که کد را به صورت External می نویسند و نیاز به وارد کردن کلاس ها قبل از استفاده از آنها را دارند نیز در کد زیر مجموعه کلاس ها وارد شده قابل مشاهده می باشد.

این کد برای تمامی ورژن های نرم افزار فلش که اکشن اسکریپت ۳ را پشتبانی می کنند قابل استفاده می باشد

کد نهایی پروژه پخش صدا در اکش اسکریپت ۳ »

import flash.media.Sound;
import flash.net.URLRequest;
import flash.media.SoundChannel;
import flash.events.MouseEvent;
import flash.media.SoundTransform;

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var myTransform:SoundTransform = new SoundTransform();
var lastPosition:Number = 0;
var isPlay:Boolean = true;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play(0);
myTransform.volume = 0.5;
myChannel.soundTransform = myTransform;

pause_btn.addEventListener(MouseEvent.CLICK , onClickPause);
function onClickPause(e:MouseEvent)
{
	lastPosition = myChannel.position;
	myChannel.stop();
	isPlay = false;
}

play_btn.addEventListener(MouseEvent.CLICK , onClickPlay);
function onClickPlay(e:MouseEvent)
{
	if (! isPlay)
	{
		myChannel = mySound.play(lastPosition);
		myChannel.soundTransform = myTransform;
		isPlay = true;
	}
}

stop_btn.addEventListener(MouseEvent.CLICK, onClickStop);

function onClickStop(e:MouseEvent):void
{
	myChannel.stop();
	lastPosition = 0;
	isPlay = false;
}

توصبه می شود بخش اول مبحث پخش صدا در اکشن اسکریپت ۳ و بخش دوم مبحث پخش صدا در اکشن اسکریپت ۳ و بخش سوم مبحث پخش صدا در اکشن اسکریپت ۳ را نیز مطالعه نمایید

امید است که از این بخش از آموزش ها نهایت بهره را برده باشید.
موفق و پیروز باشید

در ادامه  بخش دوم مبحث پخش صدا در اکشن اسکریپت ۳ به بخش آخر این مبحث می پردازیم :

Pause کرد صدا

در واقع اکشن اسکریپت متدی برای pause کردن صدا ندارد و عملی که می بایست انجام شود Stop کردن صدا می باشد و برای ادامه می بایست عمل play از محل ادامه تعیین شود.
این عمل نیاز به این دارد که ما آخرین محل در حال پخش را قبل از Stop کردن دریافت کنیم تا در زمان ادامه دادن بتوان با استفاده از play از ادامه صدا عمل پخش را شروع کنیم.
برای این کار نیاز داریم از soundChannel و خصوصیت .position استفاده کنیم تا بتوانیم این مقدار را در مرحله بعد در متد .play استفاده کنیم.

برای شروع این پروژه ابتدا از پانل Components دکمه ای را می کشیم و به Stage وارد می کنیم و instance name آن را play_btn قرار می دهیم و label آن را Play قرار می دهیم و دکمه دیگر با instance name ی با مقدار pause_btn قرار دهید یا lable و instance name مربوطه به مثال قبلی را با مقدار های Pause و pause_btn تغییر دهید. در نهایت می بایست مانند تصیر زیر دو دکمه در صفحه داشته باشید.

حال به بخش اکشن اسکریپت بر می گردیم و ابتدا می بایست همه کد های مربوطه به stop_btn مثال قبلی را حذف نمایید.

کد هایی که می بایست حذف شود:

stop_btn.addEventListener(MouseEvent.CLICK, onClickStop);
function onClickStop(e:MouseEvent):void{
myChannel.stop();

برای این که ما آخرین محل پخش شدن را در دسترس داشته باشیم نیاز داریم یک variable ایجاد کنیم و مقدار آخرین محل پخش را در زمان Stop کردن در آن قرار دهیم. ما به راحتی می توانیم یک variable ایجاد کنیم و مقدار آن را به صورت پیش فرض رو صفر ۰ قرار دهیم. ما نام این variable را lastPosition قرار می دهیم به کد زیر دقت نمایید :

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var lastPosition:Number = 0;
mySound.load(new URLRequest(”myFavSong.mp3″));
myChannel = mySound.play();

حال ما به کدهای مربوط به دکمه Pause می پردازیم زمانی که بر روی این دکمه کلیک می شود ما ابتدا به lastPosition مقداری که از SoundChannel ما دریافت می شود و خصوصیت position آن دریافت می کنیم. در زیر به کد مربوطه به pause_btn دقت نمایید :

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var lastPosition:Number = 0;
mySound.load(new URLRequest(”myFavSong.mp3″));
myChannel = mySound.play();
pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);
function onClickPause(e:MouseEvent):void{
lastPosition = myChannel.position;
myChannel.stop();
}

ما حال می بایست در دکمه Play تغییراتی انجام دهیم که تا بتواند در زمان کلیک از آخرین محل عمل پخش را انجام دهد این کار به راحتی با دادن مقدار lastPosition به اولین آرگمان مربوطه به متد Play این کار امکان پذیر می باشد ، اگر توجه کرده باشید در ابتدا مقدار lastPosition را روی ۰ قرار دادیم با این کار در صورتی که تا به حال عمل pause انجام نشده باشد عمل play از محل ۰ که همان ابتدای صوت ما می باشد شروع می شود ، توجه داشته باشید که می بایست متد play را به myChannel نسبت دهید :

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var lastPosition:Number = 0;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play();
pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);
function onClickPause(e:MouseEvent):void
{
	lastPosition = myChannel.position;
	myChannel.stop();
}
play_btn.addEventListener(MouseEvent.CLICK, onClickPlay);
function onClickPlay(e:MouseEvent):void
{
	myChannel = mySound.play(lastPosition);
}

حالا وقت این رسیده که با Ctrl+Enter پروژه خودتون تست نمایید.

تغییر ولوم (Volume) صدا

در آخر بخش صدا ها به ولوم صدا و کنترل بر آن توسط SoundChannel می پردازیم ، برای تغییر در ولوم صدا نیاز به استفاده از کلاس SoundTransform و خصوصیت SoundChannel.soundTransform می باشد.

کلاس SoundTransform دارای خصوصیات متغیری می باشد که مهم ترین برای ما .volome می باشد. استفاده از SoundTransform بسیار ساده می باشد همه چیزی که نیاز دارید این است که ابتدا یک متغیر بسازید و کلاس را به آن نسبت دهید و خصوصیات را اعمال نمایید و به خصوصیت .soundTransform مربوط به SoundChannel مربوطه متغیر ساخته شده را اعمال نمایید.

در ادامه کار را با ایجاد نمونه ای از کلاس SoundTransform و اعمال آن به myTransform شروع می کنیم :

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var myTransform = new SoundTransform();
var lastPosition:Number = 0;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play();

pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);

function onClickPause(e:MouseEvent):void
{
	lastPosition = myChannel.position;
	myChannel.stop();
}

play_btn.addEventListener(MouseEvent.CLICK, onClickPlay);

function onClickPlay(e:MouseEvent):void
{
	myChannel = mySound.play(lastPosition);
}

در این مرحله ما می بایست مقداری به خصوصیت .volume  بر روی این نمونه بدهیم.مقداری مربوطه به خصوصیت .volume مقداری بین ۰ تا ۱ می باشد که ۱ به معنای نهایت ولوم و ۰ به معنای بدون صدا بودن می باشد ، شما می توانید مقدار های اعشاری بین ۰ تا ۱ را برای مقدار دهی استفاده کنید به طور مثال ۰.۵ به معنای ۵۰%  صدا می باشد.

در این مرحله ولوم را بر روی ۰.۵ که صدای متوسط می باشد (۵۰%) قرار می دهیم.

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var myTransform = new SoundTransform();
var lastPosition:Number = 0;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play();
myTransform.volume = 0.5;

pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);

function onClickPause(e:MouseEvent):void
{
	lastPosition = myChannel.position;
	myChannel.stop();
}

play_btn.addEventListener(MouseEvent.CLICK, onClickPlay);

function onClickPlay(e:MouseEvent):void
{
	myChannel = mySound.play(lastPosition);
}

حال این transform  را به عنوان خصوصیت .soundTransform مربوطه به SoundChannel اعمال می کنیم.

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var myTransform = new SoundTransform();
var lastPosition:Number = 0;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play();
myTransform.volume = 0.5;
myChannel.soundTransform = myTransform;

pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);

function onClickPause(e:MouseEvent):void
{
	lastPosition = myChannel.position;
	myChannel.stop();
}

play_btn.addEventListener(MouseEvent.CLICK, onClickPlay);

function onClickPlay(e:MouseEvent):void
{
	myChannel = mySound.play(lastPosition);
}

شما می بایست همیشه به یاد داشته باشید استفاده از .soundTransform می بایست بعد از قرار دادن شی صدا در channel  شما باشد و نه قبل از آن. شما می توانید ولوم را با تست کردن Movie و صدا را به صورت متوسط بشنوید ولی با Pause و Play کردن صدا متوجه خواهید شد صدا دوباره زیاد می شود ، دلیل این می باشد که زمانی که صدای جدیدی به Channel وارد می کنید  همه soundTransform ها حذف می شود. ما این مورد را با اعمال  دوباره خصوصیت .soundTransform واقع در تابع onClickPlay حل می کنیم :

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
var myTransform = new SoundTransform();
var lastPosition:Number = 0;
mySound.load(new URLRequest("myFavSong.mp3"));
myChannel = mySound.play();
myTransform.volume = 0.5;
myChannel.soundTransform = myTransform;

pause_btn.addEventListener(MouseEvent.CLICK, onClickPause);

function onClickPause(e:MouseEvent):void
{
	lastPosition = myChannel.position;
	myChannel.stop();
}

play_btn.addEventListener(MouseEvent.CLICK, onClickPlay);

function onClickPlay(e:MouseEvent):void
{
	myChannel = mySound.play(lastPosition);
	myChannel.soundTransform = myTransform;
}

حال movie را تست نمایید و به این نکته دقت کنید که این بار با Pause و Play کردن در ولوم صدا تغییری ایجاد نمی شود.

توصیه می شود بخش اول صداها در اکشن اسکریپت ۳ و بخش دوم صداها در اکشن اسکریپت ۳ نیز مطالعه شود.

در ادامه  بخش اول مبحث پخش صدا در اکشن اسکریپت ۳ به موارد دیگر ذکر شده در آن مطلب می پردازیم :

پخش یک فایل صوتی خارجی (خارج از فلش )

پخش کردن یک فایل صوتی خارجی ساده تر از پخش فایل صوتی داخل فلش می باشد زیرا شما نیازی به وارد کردن فایل برای ساخت کلاسی برای فراخوانی فایل ندارید.

برای شروع یک پروژه جدید فلش ایجاد کنید و آن را در محلی مثل دسکتاپ ذخیره کنید و فایل .mp3 مربوطه را نیر در همان محل قرار دهید و فایل صوتی را به myFavSong.mp3 تغییر نام دهید.

حال به پروژه FLa خود برگردید و پنل اکشن را باز نمایید با دکمه F9 و نوشتن کد را شروع می کنیم ، در ابتدا سراغ ساختن new از کلاس Sound می نمایید و آن را به mySound مقدار دهی می کنیم و بعد با استفاده از متد .load این کلاس اقدام به بارگزاری فایل مریوطه می کنیم و در نهایت با استفاده از متد .play اقدام به پخش صدای بارگزاری شده می نماییم.

در زیر به که موارد ذکر شده دقت نمایید :

var mySound:Sound = new Sound();
mySound.load(new URLRequest(”myFavSong.mp3″));
mySound.play();

همان طور که در کد بالا مشاهده می کنید برای استفاده از آدرس یک فایل در بخش load در AS3 از کلاس URLRequerst استفاده می کنیم برای اطلاعات بیشتر در مورد این کلاس می توانید به راهنمای نرم افزار فلش مراجعه نمایید. شما هم اکنون می توانید پروژه را تست نمایید و پخش شدن فایل خارجی بارگزاری شده را تست نمایید.

Stop کردن صدا

تا اینجا درباره انواع پخش کردن صدا با اکشن صحبت کردیم در ادامه به نحوه Stop کردن و یک مثال خواهیم پرداخت.
نکته ای که وجود دارد این است که کلاس Sound متدی برای Stop کردن صدا ندارد و ما برای این کار می بایست از کلاس SoundChannel کمک بگیریم. ما می بایست یک SoundChannel یا کانال صوتی ایجاد کنیم و عملکرد متد play کلاس Sound رو با اون برابر قرار بدیم تا بتونیم از متد SoundCannel برای صدای خودمون استفاده کنیم.

در زیر به توضیحی از متدهای کلاس SoundChannel می پردازیم:

• .stop() –این متد صدای که درون کانال مورد نظری در حال پخش است را Stop می کند.
• .position – این متد محل جاری صدای در حال پخش را در کانال مورد نظر ما بر می گرداند.
• .soundTransform – برای تغییر صدا مثل ولوم و جا به جایی بین پخش سمت چپ و راست می باشد.

در ادامه ما یک پروژه جدید فلش ایجاد می کنیم و قصد داریم یه فایل صوتی خارجی را بارگزاری و پخش کنیم و با یک دکمه Stop در زمان کلیک بر روی آن عمل پخش را Stop نماییم

در مرحله اول یک دکمه Button از پانل کامپوننت ها Window>Components درگ کرده و در صفحه قرار دهید و instance name آن را stop_btn قرار دهید ، شما می تونید از تب پارامتر های کامپوننت lable دکمه را به Stop تغییر دهید.

هم اکنون دکمه ای ایجاد کردیم که در زمان کلیک بر روی آن صدا می بایست Stop شود.
پنل اکشن را باز نمایید و یا بر روی تنها فریم موجود در تایم لاین TimeLine راست کلیک کرد و Actions را انتخاب نمایید تا پانل اکشن نمایش داده شود.

مرحله بعد شروع نوشتن کد ها می باشد طبق کدهایی که در مرحله های قبلی توضیح دادیم کلاس Sound را برای بارگزاری صدا ایجاد می کنیم و صدا را با متد play پخش می کنیم.

var mySound:Sound = new Sound();
mySound.load(new URLRequest(”myFavSong.mp3″));
mySound.play();

ما برای کنترل بر روی صدا و اعمال متد Stop همان طور که در اول هم گفتیم می بایست از SoundChannel استفاده کنیم در کدی در زیر می بینید ما این کلاس تعریف کردیم:

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
mySound.load(new URLRequest(”myFavSong.mp3″));
mySound.play();

برای این که کلاس SoundChannel بر روی صدای ما کنترل داشته باشد نیاز به این داریم که پیوندی بین این دو ایجاد نماییم و این کار را با جا به جایی خط آخر کد بالا انجام می دهیم ، در واقع عمل play را به کلاس SoundChannel که در اینجا با myChannel تعریف شده می دهیم.

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
mySound.load(new URLRequest(”myFavSong.mp3″));
myChannel = mySound.play();

حال به راحتی می توانید با ایجاد رویداد برای دکمه از متد stop مریوط به کلاس SoundChannel استفاده کنیم.

var mySound:Sound = new Sound();
var myChannel:SoundChannel = new SoundChannel();
mySound.load(new URLRequest(”myFavSong.mp3″));
myChannel = mySound.play();

stop_btn.addEventListener(MouseEvent.CLICK, onClickStop);

function onClickStop(e:MouseEvent):void{
myChannel.stop();
}

حال می توانید پروژه را تست نمایید در زمان اجرا به صورت خودکار صدا می بایست پخش شود و با کلیک بر روی دکمه Stop می بایست صداد Stop شود.

توصبه می شود بخش اول مبحث پخش صدا در اکشن اسکریپت ۳ را نیز مطالعه نمایید